// minibossnpc.txt
// Like basicnpc, but character automatically talks to party when they get 
// within 6 spaces or combat starts. The dialogue is meant to only
// be said once, and not again. This script is meant to be for
// foes of the party.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.

//   Cell 3 - Dialogue node the character talks from.


begincreaturescript;

variables;

short i,target;
short tried_return = 0;
short talk_done = 0;
short last_abil;
short last_abil2;
short mess1 = 0;
short mess2 = 0;
short bonus = 0;

body;

beginstate INIT_STATE;
	//set_name(ME,"");
	//set_level(ME,);
	change_max_health(ME,250);
	set_boss_level(ME,2);
	set_coloradj(ME,0);
	set_scaling(ME,100);
	
	set_courage(ME,100);
	
	set_resistance(ME,0,gf(16,19));
	set_resistance(ME,1,gf(16,19));
	set_resistance(ME,2,gf(16,19));
	set_resistance(ME,3,gf(16,19));
	set_resistance(ME,4,gf(16,19));
	set_resistance(ME,5,gf(16,19));
	set_resistance(ME,6,gf(16,19));
	set_resistance(ME,7,100);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	last_abil2 = get_current_tick();
	break;

beginstate DEAD_STATE;
	set_terrain(0,59,2,0);
	sf(16,16,1);
	erase_char(1669);
	erase_char(1670);
	erase_char(1671);
	erase_char(1614);
	erase_char(1615);
	ok_dlog(52,3);
	//sf(,,);
	//begin_talk_mode();
break;

beginstate START_STATE; 
		set_attack_bonus(ME,bonus * (difficulty() + 3));

	set_resistance(ME,0,gf(16,19));
	set_resistance(ME,1,gf(16,19));
	set_resistance(ME,2,gf(16,19));
	set_resistance(ME,3,gf(16,19));
	set_resistance(ME,4,gf(16,19));
	set_resistance(ME,5,gf(16,19));
	set_resistance(ME,6,gf(16,19));

	if (talk_done == 0) {
		if (((get_nearest_party_char(5) >= 0) || (who_shot_me() >= 0)) && (in_boat() == FALSE)) {
			talk_done = 1;
			talk_no_exit(30);
			}
		}

		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,8,0)) {

		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());

		do_attack();
		set_state(3);
		}

	// if we're hostile, hunt party down
	if (get_attitude(ME) >= 10) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}		

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
		set_attack_bonus(ME,bonus * (difficulty() + 3));

	set_resistance(ME,0,gf(16,19));
	set_resistance(ME,1,gf(16,19));
	set_resistance(ME,2,gf(16,19));
	set_resistance(ME,3,gf(16,19));
	set_resistance(ME,4,gf(16,19));
	set_resistance(ME,5,gf(16,19));
	set_resistance(ME,6,gf(16,19));

	if (talk_done == 0) {
		if (((get_nearest_party_char(5) >= 0) || (who_shot_me() >= 0)) && (in_boat() == FALSE)) {
			talk_done = 1;
			talk_no_exit(30);
			}
		}


	if (target_ok() == FALSE)
		set_state(START_STATE);


	if (tick_difference(last_abil,get_current_tick()) > 1) {
		last_abil = get_current_tick();

		bonus = bonus + 1;
		set_attack_bonus(ME,bonus * (difficulty() + 3));
		
		i = get_ran(1,0,3);
		if (i != 1) {
			if (char_ok(1609 + i) == FALSE) {
				spawn_creature(1609 + i);
				set_level(1609 + i,30);
				set_name(1609 + i,"Garzahd's Aide");
				}
			}
		
		if ((mess2 > 0) && (difficulty() > 0)) {
			i = get_ran(1,0,1);
			if (difficulty() > 1)
				i = i + 2;
			if (char_ok(1669 + i)) {
				i = get_ran(1,0,1);
				if (difficulty() > 1)
					i = i + 2;
				}
			if (char_ok(1669 + i) == FALSE) {
				run_char_animation(3,1,35);	
				pc_heard_sound_delay(171,100);	
				
				spawn_creature(1669 + i);
				set_level(1669 + i,30);
				if (difficulty() > 1)
					set_name(1669 + i,"Radiant Nullbug");
					else set_name(1669 + i,"Writhing Worm");
				
				print_str_color("Garzahd calls forth a slimy horror!",2);
				end();
				}
			
			}
		}

	if ((mess1 > 0) && (difficulty() > 0) && (tick_difference(last_abil2,get_current_tick()) > 1)) {
		last_abil2 = get_current_tick();

		run_char_animation(3,1,35);	
		pc_heard_sound_delay(189,100);	
		place_particle_num(get_target(),1,1,8);
		run_text_on_char(get_target(),"Poof!",0);
		print_str_color("Garzahd banishes his target!",2);
		
		if (difficulty() > 1)
			set_char_status(get_target(),31,5);
		if (difficulty() > 2)
			set_char_status(get_target(),1,8);

		if (char_ok(1614) == FALSE) {			
			spawn_creature(1614);
			relocate_char(get_target(),51,16,0);
			}
			else if (char_ok(1615) == FALSE) {			
				spawn_creature(1615);
				relocate_char(get_target(),55,16,0);
				}
				else if (get_ran(1,0,100) < 50)
					relocate_char(get_target(),56,25,0);
					else relocate_char(get_target(),50,25,0);
			
		set_foe_target(ME,-1);
		set_state(START_STATE);

		}
		
	//	run_char_animation(3,1,35);	
	//	pc_heard_sound_delay(171,100);	
	
	//	place_particle_num(,1,1,8);
	
	if ((talk_done > 0) && (mess1 == 0) && (get_health(ME) < (get_max_health(ME) * 4) / 5)) {
		mess1 = 1;
		last_abil2 = get_current_tick();
		talk_no_exit(40);
		}
	if ((mess1 > 0) && (mess2 == 0) && (get_health(ME) < (get_max_health(ME) * 1) / 3)) {
		mess2 = 1;
		talk_no_exit(70);
		}
		
	if ((my_dist_from_start() >= 25) && (tried_return == 0)) {
		tried_return = 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}

	do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_named_str(ME,"doesn't respond.");
		end();
		}
	talk_done = 1;
	talk_no_exit(get_memory_cell(3));
break;