// summonnpc.txt
// Like basicnpc, but creature can potentially summon a creature every turn or
// more to help it
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5,6,7 - Character ids of creatures it can summon
//   Cell 8 - number of turns between summons, defaults to 2
//   Cell 9 - If 0, summoned creature is normal. Otherwise, the amount that it
//      is buffed

begincreaturescript;

variables;

short i,target;
short tried_return = 0;
short turns_between = 2;
short last_abil;
short char_got;

body;

beginstate INIT_STATE;
	set_boss_level(ME,1);
	add_ability(ME, 9, -1, 0);
	
	last_abil = get_current_tick();
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			tried_return = 0;
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);

	if ((my_dist_from_start() >= 25) && (tried_return == 0)) {
		tried_return = 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}

	char_got = 0;
	
	if (tick_difference(last_abil,get_current_tick()) >= turns_between) {
		i = get_ran(1,0,3);
		if ((i == 0) && (get_memory_cell(4) > 0) && (char_ok(get_memory_cell(4)) == FALSE)) {
				if (summon_creature(get_memory_cell(4))) 
					char_got = get_memory_cell(4);
				}
		if ((i == 1) && (get_memory_cell(5) > 0) && (char_ok(get_memory_cell(5)) == FALSE)) {
				if (summon_creature(get_memory_cell(5))) 
					char_got = get_memory_cell(5);
				}
		if ((i == 2) && (get_memory_cell(6) > 0) && (char_ok(get_memory_cell(6)) == FALSE)) {
				if (summon_creature(get_memory_cell(6))) 
					char_got = get_memory_cell(6);
				}
		if ((i == 3) && (get_memory_cell(7) > 0) && (char_ok(get_memory_cell(7)) == FALSE)) {
				if (summon_creature(get_memory_cell(7))) 
					char_got = get_memory_cell(7);
			}
			
		}
	if (char_got > 0) {
		print_named_str(ME,"summons assistance.");
		place_particle_num(char_got,1,1,8);
		set_level(char_got,25);
		set_attack_bonus(ME,5 + 5 * difficulty());
		set_summon_level(char_got,1);
		pc_heard_sound_delay(171,100);						
		last_abil = get_current_tick();
		run_char_animation(3,1,35);	
		end();
		}
	
	do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
			
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;