// hunter.txt
// Important script. Functions like basicnpc, but with a key difference. If it 
// is hostile, it will hunt down the party to attack. Note that this creature
// doesn't default to acting from a long way away. This needs to be set
// manually with the set_act_at_dist call.

// if you don't want it to attack right away, set its attitude to be neutral and 
//  change its attitude with a call when you want it to attack.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	set_level(ME,26);
	set_summon_level(ME,1);
	if (gf(59,19) > 100)
		sf(59,19,0);
	
	set_name(ME,"Wispy Construct");
	
	inc_flag(59,19,1);
	if (gf(59,19) % 3 == 1) {
		set_name(ME,"Hammer Construct");
		set_attack_bonus(ME,50);
		set_coloradj(ME,1);
		}
	if ((gf(59,19) % 3 == 2) && (difficulty() > 1)) {
		set_name(ME,"Terror Construct");
		set_new_abil(ME,12);
		set_coloradj(ME,2);
		}
	if ((gf(59,19) % 3 == 0) && (difficulty() > 2)) {
		set_name(ME,"Nullity Construct");
		set_new_abil(ME,14);
		set_coloradj(ME,4);
		}
		
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if (gf(59,21) > 1) {
		print_named_str(ME,"vanishes.");
		erase_char(ME);
		end();
		}
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	// if we're hostile, hunt party down
	if (get_attitude(ME) >= 10) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}


	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (gf(59,21) > 1) {
		print_named_str(ME,"vanishes.");
		erase_char(ME);
		end();
		}
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;

	begin_talk_mode(get_memory_cell(3));
break;