// forcetalk.txt
// Exactly like basicnpc, but when party gets close, character hunts them down 
// and talks to them
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - Stuff done flag. Set to 1 if the character has hunted them down 
//     once.
//   Cell 6 - range to initiate talking, defaults to 14 if left at 1

begincreaturescript;

variables;

short i,target;
short hunted_party = 0;
short hunt_range = 22;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	if (get_memory_cell(6) != 0)
		hunt_range = get_memory_cell(6);
	
	if ((get_memory_cell(4) > 0) && (get_flag(get_memory_cell(4),get_memory_cell(5)) > 0))
		hunted_party = 1;
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if ((in_boat() == FALSE) && (dist_to_party() <= hunt_range) && (hunted_party == 0)) {
		set_state(4);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate 4; // hunt party
	if (hunted_party > 0)
		set_state(START_STATE);
	if (in_boat())
		set_state(START_STATE);
	if (gf(get_memory_cell(4),get_memory_cell(5)) > 0)
		set_state(START_STATE);

	if ((can_see_char(30000)) && ((get_nearest_party_char(4) >= 0) || (approach_char(ME,30000,3)))) {
		if (get_memory_cell(4) > 0)
			set_flag(get_memory_cell(4),get_memory_cell(5),1);
		hunted_party = 1;
		talk_no_exit(get_memory_cell(3));
		}
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
break;

beginstate TALKING_STATE;
	hunted_party = 1;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	if (get_memory_cell(4) > 0)
		set_flag(get_memory_cell(4),get_memory_cell(5),1);
	begin_talk_mode(get_memory_cell(3));
break;