//groupnpc.txt - Like basicnpc.txt. Basically, it fidgets around and attacks anything 
//it sees it hates. Also, if it becomes hostile, it sends an alert message to everyone 
//in its group, if it is in a group.
// Memory Cells:
//   Cell 0 - If 0, default behavior. If 1, it doesnŐt fidget.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//   Cell 3 - Number of state when talked to. Plays default text if 0.

begincreaturescript;

variables;

short i,target;
short sent_alert = 0;
short did_pot = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Portal Defender");
	change_max_health(ME,150);
	
	set_level(ME,30);
	
	if ((creature_type(ME) >= 185) && (creature_type(ME) >= 192))
		set_name(ME,"Vahnatai Master");

	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	break;

beginstate DEAD_STATE;
	if ((what_group_in(ME) >= 0) && (sent_alert == 0)) {
		set_attitude(30000 + what_group_in(ME),10);
		alert_char(30000 + what_group_in(ME));
		sent_alert = 1;
		}

	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 24)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	set_attack_bonus(ME,8 + (5 * difficulty()));

	if ((what_group_in(ME) >= 0) && (sent_alert == 0)) {
		set_attitude(30000 + what_group_in(ME),10);
		alert_char(30000 + what_group_in(ME));
		sent_alert = 1;
		}

	if ((did_pot == 0) && (get_health(ME) < get_max_health(ME) / 2)) {
		did_pot = 1;
		print_named_str(ME,"drinks a potion.");
		run_char_animation(3,1,35);	
		
		if (get_ran(1,0,100) < 33) {
			play_sound(101);
			set_char_status(ME,24,5);
			}
			else if (get_ran(1,0,100) < 50) {
				play_sound(105);
				set_char_status(ME,20,5);
				set_char_status(ME,21,5);
				}
				else {
					play_sound(101);
					set_char_status(ME,0,5);
					set_char_status(ME,4,5);
					}
		
		end();
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;