// mobsummoned.txt
// Exactly like the basicnpc scrint, but for one thing. Its for a summoned creature so, when it's far fromt he party and not fighting, moves to catch up.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short tried_return = 0;

body;

beginstate INIT_STATE;
	set_aggression(ME,100);
	set_courage(ME,100);
	break;

beginstate DEAD_STATE;

break;

beginstate START_STATE; 

	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Stay close to party
	if ((get_nearest_party_char(4) < 0) && (get_attitude(ME) < 10)) {
		if (dist_to_party() >= 12) {
			telep_char_to_char(ME,random_group_member(0),0);
			print_named_str(ME,"hurries to catch up with you.");
			set_foe_target(ME,-1);
			}
			else approach_char(ME,30000,2);
		}
		

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

	if (target_ok() == FALSE) {
		if (get_foe_target(ME,12,0) == FALSE) 
			set_state(START_STATE);
		}

	if (dist_to_party() >= 12) {
		telep_char_to_char(ME,random_group_member(0),0);
		print_named_str(ME,"hurries to catch up with you.");
		set_foe_target(ME,-1);
		set_state(START_STATE);
		}

	do_attack();
break;


beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;