// naturenpc.txt
// Like basicnpc, but when the creatur egets close to the PC, has a chance of
// going hostile if natuyre lore not high enough
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Nature lore necessary to keep happy. if 0, then defaults to half 
//     of level

begincreaturescript;

variables;

short i,target;
short tried_return = 0;
short skill_checked = 0;
short skill_needed;
short sent_alert = 0;

body;

beginstate INIT_STATE;
	set_attitude(ME,4);
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	set_aggression(ME,70);
	break;

beginstate DEAD_STATE;
	if ((what_group_in(ME) >= 0) && (sent_alert == 0)) {
		set_attitude(30000 + what_group_in(ME),10);
		alert_char(30000 + what_group_in(ME));
		sent_alert = 1;
		}

	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if ((get_nearest_party_char(6) >= 0) && (get_attitude(ME) < 10) && (skill_checked == 0) && (in_boat() == FALSE)) {
		skill_checked = 1;

		skill_needed = get_memory_cell(4);
		if (skill_needed == 0)
			skill_needed = get_level(ME) / 2;

		if (get_stat_total(16) < skill_needed) {
			print_named_str(ME,"gets nervous, and you aren't able to calm it.");
			set_attitude(ME,10);
			if (get_stat_total(16) < skill_needed - 2) {
				print_str_color("  Your clumsy attempt to calm it only makes it angrier.",2);
				set_attack_bonus(ME,get_level(ME) / 4);
				force_char_status(ME,1,3);
				}
		
			if ((what_group_in(ME) >= 0) && (sent_alert == 0)) {
				set_attitude(30000 + what_group_in(ME),10);
				alert_char(30000 + what_group_in(ME));
				sent_alert = 1;
				}
			}
			else print_named_str(ME,"seems nervous, but you are able to calm it.");
		if (gf(130,3) < 4) { //### change flag in future games
			inc_flag(130,3,1);
			print_str_color("  (Some monsters will attack if your Nature Lore skill is inadequate.)",2);
			}
		}
	
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			tried_return = 0;
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);

	if ((what_group_in(ME) >= 0) && (sent_alert == 0)) {
		set_attitude(30000 + what_group_in(ME),10);
		alert_char(30000 + what_group_in(ME));
		sent_alert = 1;
		}

	if ((my_dist_from_start() >= 25) && (tried_return == 0)) {
		tried_return = 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}

	do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (skill_checked == 0) {
		print_str_color("Talking: It hasn't noticed you yet. When you get close, it might attack you.",2);
		
		end();
		}
	if (get_memory_cell(3) == 0) {
		print_str_color("Talking: You managed to calm this creature. It stares at you mutely.",2);
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;