//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;
short stoprun = 0;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();

	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
	if (get_level(ME) > 3)
		set_level(ME,3);
	if (get_attitude(ME) >= 10) {
		set_name(ME,"Goblin Raider");
		set_level(ME,1);
		}
		else set_name(ME,"Young Soldier");
		
	if (gf(70,29) > 0)
		erase_char(ME);
break;

beginstate START_STATE; 
	if (gf(70,19) == 0)
		end();
		
	if (stoprun == 0) {
		// Have I been hit? Strike back!	
		if (who_shot_me() >= 0) {
			stoprun = 1;
			set_foe_target(ME,who_shot_me());
			do_attack();
			set_state(3);
			}
		
		if ((dist_to_party() <= 3) && (get_attitude(ME) >= 10))
			stoprun = 1;
			else if (dist_to_nav_point(ME,0) <= 4)
				stoprun = 1;
				else {
					approach_nav_point(ME,0,2);
					end();
					}
		}
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (dist_to_nav_point(ME,0) >= 6) {
		if (get_ran(1,1,100) < 40) 
			approach_nav_point(ME,0,2);
		}
		else  {
			fidget(ME,25);
			}
			
	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(0) == 0) {
		print_str("Talking: You make a bit of small talk, but don't learn");
		print_str("  anything interesting.");
		}
		else begin_talk_mode(get_memory_cell(0));
break;