// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home. A conversation can be set for it,
// if it's friendly.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - cant leave
//     1 - can leave
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short dest = 0;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 0)
		set_name(ME,"Starving Nephil");
		else set_name(ME,"Nephil Slave");

	set_act_at_dist(ME,1);
	set_level(ME,12);
	
	if (gf(43,11) > 0)
		erase_char(ME);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,5,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if  ((get_memory_cell(0) > 0) && (gf(43,11) > 0)) {
		if (approach_nav_point(ME,dest,2)) {
			dest = dest + 1;
			if (dest > 3) {
				print_str_color("One of the nephil slaves escapes!",2);
				award_party_xp(30,15);
				erase_char(ME);
				}
			}
		
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

	if (target_ok() == FALSE)
		set_state(START_STATE);


	do_attack();
break;


beginstate TALKING_STATE;
	if (gf(43,11) == 0)
		ok_dlog(52,1);
		else if (get_memory_cell(0) == 0)
			ok_dlog(54,1);
			else ok_dlog(56,1);
			

break;