// TOWN DIALOGUE SCRIPT
//    Town 77: Small Slith Fort

begintalkscript;

variables;

short i,j,k,r1,choice;

// Ahkas-Ahss

begintalknode;
	tag = 10;
	state = -1;
	nextstate = 1;
	question = "Ahkas-Ahss";
	text1 = "There is an unarmed slith sitting in this narrow cell. His scales are pale and lack the normal glossy sheen. He looks up at you nervously.";
	text2 = "When he realizes that he isn't about to die, he says, _I am Ahkas'Ahss, soldier. Prisoner of the servantsss of Sss'Thsss. Rescuer? I hope._";
	text5 = "Ahkas'Ahss slumps against the wall, exhausted and half-starved by his confinement.";
	action = INTRO;
	

begintalknode;
	state = 1;
	nextstate = 2;
	question = "_Why are you locked up?_";
	text1 = "_The foul slithsss here imprisoned me. I can now escape, if you do not kill me._";

begintalknode;
	state = 2;
	nextstate = 3;
	question = "_Who were the sliths here?_";
	text1 = "_These were renegade slithsss, part of the army of foul Sss'Thsss. When Sss'Thsss was slain and his castle dessstroyed, most of hisss servantsss sued for peace. We do not all hate humansss. But then, some of them fled, to keep killing and fighting._";
	text2 = "_They caught me. They were going to sacrifice me._";

begintalknode;
	state = 3;
	nextstate = -1;
	question = "_Sacrificed for what?_";
	text1 = "_I was to be sacrificed to Sss'Thsss, the foul warlord the humans have slain._ He nods. _We slithsss are a people of justice. And he received hisss, as will we all._";

begintalknode;
	state = 3;
	nextstate = 4;
	question = "_Most sliths are peaceful?_";
	text1 = "_We are not usually a warring people. We do not all hate humansss. Many of us are friendsss to you. Not these slithsss, though. They should die._";

begintalknode;
	state = 4;
	nextstate = -1;
	question = "_Death is a severe penalty._";
	text1 = "_I know it. They are but brigandsss now. Death would be the only appropriate justice._";

begintalknode;
	state = 1;
	nextstate = 7;
	question = "_Who is Sss'Thsss?_";
	text1 = "_The warlord, the barbarian, the dead one. He mastered the tribesss around here. Led them to war against humansss._";

begintalknode;
	state = 7;
	nextstate = 6;
	question = "_How was Sss-Thsss slain?_";
	text1 = "_Sss-Thsss led his servants from a castle on an island. Brave Avernite raidersss killed him. Now some of his servantsss worship him as a god._ He hisses angrily. _Slith Gods are firm and jussst. He could never be one!_";

begintalknode;
	state = 6;
	nextstate = -1;
	question = "_Tell me more about those raiders._";
	text1 = "_Great humansss! Great heroessss! They are revered by all the sliths in the land Avernum. We know not what happened to them, but we remember them alwayssss._";

begintalknode;
	state = 1;
	nextstate = -1;
	question = "_You can escape now. I will not harm you._";
	text1 = "It stands, slowly, and bows to you. _Now that my guardsss are dead, I will get away, back to my family and brood. Were it not for you, I would be sacrificed. Again, I thank you._";
	text2 = "It slips out of the cell and flees.";
	action = END_TALK;
	code =
		erase_char(7700);
		sf(77,12,1);
		award_party_xp(300,10);
	break;

begintalknode;
	state = 1;
	nextstate = -1;
	question = "_Wait here. I'll make sure it is safe._";
	text1 = "_No ... I cannot take the risk. Must return to my mate, my brood. I will fear no longer. Thank you, warrior._";
	text2 = "It slips out of the cell and flees.";
	action = END_TALK;
	code =
		erase_char(7700);
		sf(77,12,1);
		award_party_xp(300,10);
	break;

