
cyoa{ road{

cyoa-choice: bandit-car-plow
	($ Thegroup .. " decides to plow the car right through the bandit roadblock and Lord Humungoid.
	" .. gThey .. " take" .. g1s .. " a lot of damage, but survive" .. g1s .. "." $) cyoa-text! sting12rnd--all bitefx car-plowthrough someicon
;

cyoa-choice: bandit-car-paranoid
	($ cname .. " figured out a plan during the speech." $) cyoa-text!
	cpet? if
		($ cHe .. " starts honking the horn. The bandits are amused by the sight of an animal doing this. They decide to let " .. thegroup .. " pass. All part of the plan!" $)
	else
		($ cHe .. " suddenly jams on the gas pedal and turns hard. The car shoots through a small gap in the roadblock, then keeps going. 
		By the time the bandits react, " .. thegroup .. " already has too much of a head start to be worth chasing." $)
	then +crtext morale++all witsattREV goodfx
;

cyoa-bridge: bandit-car-coolit
	cpet? if
		($ "After a dramatic pause, " .. cname .. " farts. It echoes." $)
	else
		($ cname .. " tells Lord Humungoid to" .. " COOL IT." pbold $)
	then cyoa-text!
	cool-it-7 if
		char-gen to recruitee "Humungoid" recruitee .name!
		($ "Lord Humungoid has a huge change of heart.
		" .. "THERE HAS BEEN TOO MUCH VIOLENCE... TOO MUCH PAIN. BUT I HAVE AN HONORABLE COMPROMISE!" rbold .. "
		He offers a gift and safe passage!" $)
		+crtext morale3+all rescue-trainitem cooled-it goodfx
	else cool-it++
		($ "Lord Humungoid doesn't like this. The bandits take the car and all of " .. thegroup .. "'s supplies that they find." $) +crtext badfx car-abandon bandit-all morale2-all
	then witsattREV 
;

cyoa-choice: bandit-car-pay
	image-buff-bandit
	($ Thegroup .. " gets out of the car and walks away unharmed. Lord Humungoid's last words before peeling out in " .. thegroup .. "'s car are " .. "SMELL YA LATER, NERDS!" rbold $) cyoa-text! car-abandon bandit-gas
;
	

cyoa: bandit-car
	"Car Collecting Bandits" cyoa-title!
	($ "Bandits have blocked the narrow road ahead with their cars. Their leader, " .. "Lord Humungoid" pbold .. " speaks:
	" .. "JUST WALK AWAY! GIVE ME YOUR CAR! YOUR OIL! THE GASOLINE! AND I WILL SPARE YOUR LIVES.
	I AWAIT YOUR ANSWER." rbold $) cyoa-text!
		choice( "Give up the car and all gas" )choice: bandit-car-pay
		bandit-fight
		most-paranoid if
			charchoice( " already has a plan" )choice: bandit-car-paranoid
		then
		most-grating if
			charchoice( " tells Bandits to 'Cool It'" fcoolit )choice: bandit-car-coolit
		then
		choice( "Plow through them!" )choice: bandit-car-plow
;

// Medical bandits

cyoa-choice: bandit-medic-help
	($ cname .. " offers to heal the injured bandit with " .. chis .. " medical know-how. " $) cyoa-text!
	medicalroll cmedical+ or if
		($ cHe .. " fixes things right up! The bandits let " .. thegroup .. " go." $) +text goodfx
	else
		($ cHe .. " ends up making things worse! The bandits aren't very happy." $) +text
		bandithurt bitefx
	then medicalREV medical++
;

cyoa-choice: bandit-medic-paranoid
	cpet? if
		($ cname .. " knew that something was very wrong the whole time. Due to " .. chis .. " " .. cgrowlhiss .. "ing, " .. everyone .. " is warned early. " .. gTheyare .. " ready to fight before the bandits are, and escape unharmed." $) 
	else
		($ "Always suspicious, " .. cname .. " hid the car and supplies before approaching the settlement. " .. cHe .. " claims to have nothing of value.
		The bandits doubt this, but can't find anything. They end up letting " .. thegroup .. " go." $)
	then cyoa-text! witsattREV goodfx
;

cyoa-bridge: bandit-medic-coolit
	cpet? if
		($ cname .. " farts in a pitch that sounds like a tiny violin." $)
	else
		($ cname .. " tells the fake traders to " .. " COOL IT." pbold $)
	then cyoa-text!
	cool-it-7 if
		char-gen to recruitee "Fake Trader" recruitee .name!
		($ "The injured bandit looks really moved by this!
		" .. "WOW! I feel so much better now!" rbold .. "
		She stands up, does a cartwheel, and orders that you be brought a gift!" $)
		+crtext morale3+all rescue-trainitem cooled-it goodfx
	else cool-it++
		($ "The bandits just stare at the " .. thegroup .. " for awhile.
		Then they take most of " .. ghis .. " supplies." $) +crtext badfx bandit-mostgas morale2-all
	then witsattREV 
;

: bandit-medic-pay
		-8 trunk-medical+
;
	

cyoa: bandit-medic
	"Trader Trap" cyoa-title!
	($ Thegroup .. " checks out what appears to be a trader settlement. " .. gTheyare .. " instead ambushed by bandits who have taken it over. One of them looks injured.
	" .. "They demand " rbold $) cyoa-text!
	solo if
		soloer ispet? if
			($ "... oh wait, it's just an animal. False alarm!" rbold .. "
			The bandits let " .. soloname .. " go!" $) +text goodfx
		then;
	then
	trunk-medical 7 > if
		($ "8 medical supplies!" rbold $) +text
		choice( "Give them 8 medical supplies" )choice: bandit-medic-pay
	else
		bandit-demand
	then
		medicalest charchoice( " offers to heal injury" )choice: bandit-medic-help
		most-grating if
			charchoice( " tells Bandits to 'Cool It'" fcoolit )choice: bandit-medic-coolit
		then
		most-paranoid if
			charchoice( " saw this coming" )choice: bandit-medic-paranoid
		then
		bandit-fight
;

// Weapon thieves

cyoa-choice: bandit-weapon-paranoid
	solo if 
		($ cname .. " felt suspicious about the campsite, so " .. che .. " left the car running. " .. cHe .. " pretends to give in to their demands, but runs to the waiting car as soon as " .. che .. " can.
		The bandits' weapons are too crappy to do anything to the car once " .. che .. "'s in, so " .. che .. " PEELS OUT." rbold $) cyoa-text! goodfx
	else
		($ cname .. " felt suspicious about the campsite, so " .. che .. " wanted to wait near the car.
		As " .. everyone .. " is being robbed, the car barrels through the campsite, plows over a tent, and then stops. The bandits are freaked out, so they flee!" $) cyoa-text!
		cpet? if 
			cdog? if 
				($ cname .. " accidentally locked " .. chim .. "self in the car and barks to be let out." $)
			else
				($ Everyone .. " is not sure if " .. cname .. " did all this on purpose or not." $)
			then +crtext
		else
			cloyalty- if
				($ notcname .. " is really surprised " .. cname .. " didn't try to steal the car. " .. cHe .. " looks nervous for a moment." $) +crtext
			then loyaltyREV
		then
	then goodfx witsattREV morale++all
;

cyoa-bridge: bandit-weapon-coolit
	cpet? if
		($ cname .. " farts and makes a really big deal about it." $)
	else
		($ cname .. " tells the bandits to" .. " COOL IT." pbold $)
	then cyoa-text!
	cool-it-7 if
		char-gen to recruitee "Crappy Bandit" recruitee .name!
		($ "The bandits really take this to heart.
		" .. "Yeah! Who needs weapons when we got friendship?" rbold .. "
		They offer a gift!" $)
		+crtext morale3+all rescue-trainitem cooled-it goodfx
	else cool-it++
		($ "The bandits all start attacking " .. cname .. ". They forget about the weapons." $) +crtext badfx ouch2-
	then witsattREV 
;

cyoa-choice: bandit-weapon-fight
	($ Thegroup .. " decides to take their chances in a fight.
		The bandits' weapons are crude, but they're still dangerous." $) cyoa-text! 
		bitefx ouch--all
;

cyoa-choice: bandit-weapon-pay
	($ Thegroup .. " ends up giving all " .. ghis .. " weapons to the bandits.
	The bandits give " .. ghim .. " him some old weapons, maybe feeling some guilt." $) cyoa-text! 0weaponsall trunk.clear morale2-all someicon badfx
	3 WEAPON_NAIL trunk.weapon+ 2 WEAPON_REBAR trunk.weapon+ 1 WEAPON_FISHING trunk.weapon+
	1 WEAPON_PARKING trunk.weapon+
;

cyoa-choice: bandit-weapon-calmshot
	($ cname .. " aims " .. ghis .. " weapon at lightning speeds and blasts all the bandits' flimsy weapons apart.
	The bandits start running!" $) cyoa-text! goodfx shootingREV temperREV shooting++
;
	

cyoa: bandit-weapon
	"Weapon Stealing Bandits" cyoa-title!
	($ "As " .. thegroup .. " explores a campsite, " .. gtheyare .. " ambushed by bandits. They brandish makeshift weapons.
	" .. "They demand all of your weapons." rbold .. "
		This is ludicrous. Not even bandits will usually do this, as it's a slow but sure death sentence." $) cyoa-text!
		calmshot-check if
			charchoice( " quickdraws and fires" )choice: bandit-weapon-calmshot
		else
			choice( "Fight the bandits!" )choice: bandit-weapon-fight
		then
		most-paranoid if
			solo if charchoice( " left the car running" )choice: bandit-weapon-paranoid
			else charchoice( " comes to the rescue" )choice: bandit-weapon-paranoid then
		then
		most-grating if
			charchoice( " tells Bandits to 'Cool It'" fcoolit )choice: bandit-weapon-coolit
		then
		bandit-charm
		choice( "Give up all of the weapons!" )choice: bandit-weapon-pay
;

cyoa-choice: bandit-loyal-pick
	cicon
	($ cname .. " is sent to distract the bandits so they leave their car checkpoint." $) cyoa-text!
	cloyalty- if
		($ cname .. " instantly turns on " .. everyone .. " and joins the bandits, instead." $) +crtext
		loyaltyREV decruit-bad
		($ Thegroup .. " is attacked! " .. gThey .. " attempt" .. g1s .. " to escape..." $) +crtext
		bandithurt
	then;
	($ cname .. " doesn't sell " .. everyone .. " out to the bandits! " .. cHe .. " distracts them from afar and runs. They give chase, and the car is able to get past." $) +crtext
	ctemper- if
		($ cname .. " panics while retreating. " .. cHe .. " ends up not following the plan right, and gets hurt!" $) +crtext cchar .sting12rnd-- bitefx
	else
		goodfx
	then
		($ cname .. " sneaks around the checkpoint later, and rejoins " .. everyone .. "." $) +crtext
		loyaltyREV
		
;

cyoa-choice: bandit-loyal-plow
	($ Thegroup .. " decides to plow the car right through the checkpoint.
	" .. gThey .. " take" .. g1s .. " a lot of damage, but survive" .. g1s .. "." $) cyoa-text! sting12rnd--all bitefx car-plowthrough someicon
;
: bandit-loyal-plow? choice( "Plow the car through!" )choice: bandit-loyal-plow ;

cyoa-choice: bandit-loyal-paranoid
	($ cname .. " made a backup plan before being spotted." $) cyoa-text!
	($ cHe .. " retreats to a ruined building, where the bandits can't see " .. chim .. ". When they get closer, " .. che .. " jumps out through a back window, sneaks " .. chis .. " way to the car, and escapes through a now empty checkpoint!" $) +crtext goodfx
;

cyoa: bandit-loyal
	"Who can be trusted?" cyoa-title! someicon
	solo if
		($ cname .. " a group of bandits that have set up a checkpoint on the road. " .. cHe .. " has no good way to distract them, and eventually gets spotted.
		" .. "They demand " rbold $) cyoa-text!
		bandit-demand
		most-paranoid if
			charchoice( " has a plan to trick them" )choice: bandit-loyal-paranoid
		then
		bandit-charm
		bandit-loyal-plow?
		bandit-fight
	else
		($ Thegroup .. " spots a group of bandits that have set up a checkpoint on the road. Someone from the team could be sent to distract the bandits so the car can get through. 
		It would have to be someone calm and " .. "trustworthy" rbold .. "." $) cyoa-text!
			' bandit-loyal-pick 3 #cyoa-team-choice
			bandit-loyal-plow?
	then
;

} }