

cyoa{ road{ 

: camp-pic
	50 %chance if
		image-camp-1
	else
		image-camp-2
	then	
;

cyoa: walk-camp1
	camp-pic
	"RUFFIN IT" cyoa-title!
	($ "" .. Thegroup .. " finds a nice spot to camp for the night in the woods. Wind and rain move in during the night catching " .. thegroup .. " by surprise. It is a miserable night with no car to retreat to." $) cyoa-text! morale2-all +cr fullcamp
;
cyoa: walk-camp2
	image-cabin-in-woods
	"ABANDONED LUCK" cyoa-title!
	($ "" .. Thegroup .. " is fortunate to find an abandoned cabin in the woods to stay the night in. Shortly after setting up, a storm moved in. Lucky for " .. ghim .. " that " .. gthey .. " found the cabin in time." $) cyoa-text! morale++all +cr fullcamp
;
cyoa: walk-camp3
	camp-pic
	"JUST CAMPING" cyoa-title!
	($ "" .. Thegroup .. " decides to set up camp for the night and try to eat a meal." $) cyoa-text! +cr fullcamp
;
cyoa: walk-camp4
	camp-pic
	"PEACEFUL CAMP" cyoa-title!
	($ "After a long hike " .. thegroup .. " finds a nice clearing to set up camp. The weather is nice and " .. thegroup .. " is able to rest peacefully." $) morale++all cyoa-text! +cr fullcamp
;
cyoa: walk-camp5
	camp-pic
	"BUGS AND CAMPING" cyoa-title!
	($ "After a long walk " .. thegroup .. " decides to set up camp. Unfortunately " .. thegroup .. " is assaulted by mosquitoes during the night and " .. gthey .. " get" .. g1s .. " no sleep." $) cyoa-text! morale--all +cr tiredcamp
;
cyoa: walk-camp6
	camp-pic
	"LONG DAY" cyoa-title!
	($ "After an entire day of walking " .. thegroup .. " finds a safe camping spot. " .. gHe .. " is very hungry, and " .. gthey .. " eat" .. g1s .. " an extra meal." $) cyoa-text! 
	chowday +cr fullcamp
;
cyoa: walk-camp7
	camp-pic
	"ANT ATTACKS" cyoa-title!
	($ "After a hard day of looking for a car " .. thegroup .. " finds a camping spot. During the night " .. gtheyare .. " ATTACKED BY ANTS" rbold .. " and must leave without sleep." $) cyoa-text! bitefx sting--all +cr tiredcamp
;

: walk-camp8-medcheck
	most-paranoid trunk-gas 30 > and if choosechar
		($ cname .. ", thinking of the road ahead, does all " .. che .. " can to save the extra gas." $) +crtext witsattREV sting--
	else
		bandit-gas
	then
	loyalest-pass trunk-medical 1 > and if
		loyalest choosechar 
		($ cname .. ", thinking of others in need, does all " .. che .. " can to save the medical supplies." $) +crtext loyaltyREV sting--
	else
		bandit-med
	then
;
: walk-camp8-solocheck
	solo if
		($ "Being alone, " .. che .. " isn't able to grab anything else besides " .. chis .. " own weapons." $) +crtext 
	else
		($ "They grab what other supplies they can!" $) +crtext
		walk-camp8-medcheck
	then
;

cyoa-choice: walk-camp8-food
	($ Thegroup .. " manages to grab all the food before fleeing! " $) cyoa-text!
	walk-camp8-solocheck
	solo if
		trunk.killer bandit-ammo
	else
		trunk.killer bandit-ammo2 // Maybe make this take half trunk weapons later
	then +cr morale--all +cr tiredcamp
;
cyoa-choice: walk-camp8-ammo
	($ Thegroup .. " manages to grab all the ammo before fleeing! " $) cyoa-text!
	walk-camp8-solocheck
	solo if
		trunk.killer bandit-food
	else
		trunk.killer bandit-food2 // half trunk later?
	then +cr morale--all +cr tiredcamp
;
cyoa-choice: walk-camp8-weapons
	($ Thegroup .. " manages to grab all the weapons before fleeing! " $) cyoa-text!
	walk-camp8-solocheck
	solo if
		bandit-ammofood
	else
		bandit-food2 bandit-ammo2
	then +cr morale--all +cr tiredcamp
;
cyoa-choice: walk-camp8-bear
	($ Thegroup .. ", ambushed by a bear while sleeping, decides to fight! Havoc ensues!" $) cyoa-text! someicon bandithurt
	choosehuman alive? if 
		($ "The bear retreats! " .. Thegroup .. " is able to get back to sleep." $) +crtext +cr fullcamp
	then

;
cyoa-choice: walk-camp8-flee
	($ Thegroup .. " runs and abandons the camp!" $) cyoa-text!
	walk-camp8-solocheck
	trunk.killer bandit-ammofood
	+cr morale--all +cr tiredcamp
;
cyoa-choice: walk-camp8-angry
	($ cname .. " rushes to the bear, jumps up a good height, and then thumps it in the nose as hard as " .. che .. " can.
	The bear freaks out and runs!
	" .. Thegroup .. " is able to go back to sleep." $) cyoa-text!
	morale++all +cr fullcamp
;

cyoa-choice: walk-camp8-shoot
	($ cname .. " calmly retrieves one of " .. chis .. " weapons and then calmy shoots the bear with it. No big deal!
	" .. Thegroup .. " eats an enormous feast that night, but sadly don't have the time to preserve much meat for later." $) cyoa-text!
	12 trunk-food+ morale3+all sleep
;

cyoa: walk-camp8
	camp-pic
	"THAT BEAR STOLE MY STUFF" cyoa-title!
	($ Thegroup .. "'s attempt at camping is interrupted by a very angry bear. " .. gTheyare .. " forced to abandon the camp with little sleep, and must make a panicked decision about what to grab, " .. "FAST." rbold $) cyoa-text! badfx 
	trunk-food 1 > if
		choice( "Get all the food" )choice: walk-camp8-food
	then
	most-angrystrong if
		charchoice( " punches bear in the nose" )choice: walk-camp8-angry
	then
	calmshot-check if
		charchoice( " calmly blasts the bear" )choice: walk-camp8-shoot
	then
	anyammo? if
		choice( "Grab all the ammo" )choice: walk-camp8-ammo
	then 
	trunk.count 0 > if
		choice( "Grab the extra weapons" )choice: walk-camp8-weapons
	then
	choice( "Fight the deadly bear" )choice: walk-camp8-bear
	choice( "Abandon everything" )choice: walk-camp8-flee
;
} }