/////////////////////////////////////////////////////////////////////
// NFOREST.S
/////////////////////////////////////////////////////////////////////

SETUP

	IF gd_DEMO_RAAL
		Remove  gd_DEMO_RAAL
		Add		gt_PLACED_RAAL
		PlaceC	RAAL pRAAL_START
	ENDIF

	// *** BRIGANDS ***

	IF !mj_SLEPT_AT_ANDRUS
		IF !gt_PLACED_NF_BRIG
			PlaceC NF_BRIG_1 pNF_BRIG_1
			PlaceC NF_BRIG_2 pNF_BRIG_2
			PlaceC NF_BRIG_3 pNF_BRIG_3

			RunS ResetBrigandControllers
		ENDIF
	ENDIF

	// *** ANDRUS ***

	IF f_PLAYED_INTRO_PUB_VIG && !gt_PLACED_ANDRUS && !ce_ANDRUS
		PlaceC ANDRUS pANDRUS_A_BED
		Add gt_MUST_REMOVE_SCROLL
		Add gt_PLACED_ANDRUS
	ENDIF

	IF mj_BEEN_TO_HEX && !gt_PLACED_ANDRUS_DYING
		Add	gt_PLACED_ANDRUS_DYING
		PlaceC			NF_HEX_SEEKER		pHEX_SEEKER_START 
		//RemoveC NF_HEX_SEEKER
		PlaceC ANDRUS pANDRUS_DYING
		AwardOb ANDRUS staff weapon
		MeleeAttack ANDRUS
		MeleeAttack NF_HEX_SEEKER
	ENDIF

	IF mj_FREED_FARMERS
		IF !gt_PLACED_MAD_FARMER_7
			Add gt_PLACED_MAD_FARMER_7
			PlaceC MAD_FARMER_7 pMADF_7
			Wander MAD_FARMER_7
		ENDIF
	ENDIF

	//IF mj_DEFEAT_GARGOS_1
		//RemoveC ANDRUS
	//ENDIF

    IF mj_DEFEAT_GARGOS_2
        IF !gd_PLACED_NF_DRAGONS
            Add gd_PLACED_NF_DRAGONS

            PlaceC              NF_DRAGON_1 pNF_DRAGON_1
            WanderNotFar        NF_DRAGON_1 9 12

            PlaceC              NF_DRAGON_2 pNF_DRAGON_2
            WanderNotFar        NF_DRAGON_2 9 12

            PlaceC              NF_DRAGON_3 pNF_DRAGON_3
            WanderNotFar        NF_DRAGON_3 9 12

            PlaceC              NF_DRAGON_4 pNF_DRAGON_4
            WanderNotFar        NF_DRAGON_4 9 12
        ENDIF
		IF mj_RECOVER_CROWN && gd_PLACED_NF_DRAGONS
			Remove gd_PLACED_NF_DRAGONS
            KillC  NF_DRAGON_1
            KillC  NF_DRAGON_2
            KillC  NF_DRAGON_3
            KillC  NF_DRAGON_4
			KillC MAD_FARMER_7
		ENDIF
    ENDIF

END

VIG TempSetup FALSE

	RunS AndrusWeather
	Set gd_WIND_TYPE	1
	RunS CueWeather

	IF gt_PLACED_NF_BRIG
		AddBigFire 12930 15990
		AttachLoopSFXArea ig_253.wav 50 bfire
	ENDIF
	IF !f_ANDRUS_DEAD
		AddBigFire 2164 15639
		AttachLoopSFXArea ig_253.wav 50 afire
	ENDIF
	//PlaceBFlys 15196 28848
	PlaceFFlys 16611 8231
	SetLiquid ALL 750 20 5
	SetWaterType 0

	CachePortrait HEXSEEKR.BIN
	CachePortrait PC1.BIN
	CachePortrait RAAL.BIN
	CachePortrait UANDRUS.BIN

END

/////////////////////////////////////////////////////////////////////

VIG TalkToNFDragon1 MSG-iNF_DRAGON_1
	Widescreen TRUE
    StopC           NF_DRAGON_1
    EngageAndFace   NF_DRAGON_1 P
    RunS            TalkToDragonWarrior
    WanderNotFar    NF_DRAGON_1 6 12
	Widescreen FALSE
END

/////////////////////////////////////////////////////////////////////

VIG TalkToNFDragon2 MSG-iNF_DRAGON_2
	Widescreen TRUE
    StopC           NF_DRAGON_2
    EngageAndFace   NF_DRAGON_2 P
    RunS            TalkToDragonWarrior
    WanderNotFar    NF_DRAGON_2 6 12
	Widescreen FALSE
END

/////////////////////////////////////////////////////////////////////

VIG TalkToNFDragon3 MSG-iNF_DRAGON_3
	Widescreen TRUE
    StopC           NF_DRAGON_3
    EngageAndFace   NF_DRAGON_3 P
    RunS            TalkToDragonWarrior
    WanderNotFar    NF_DRAGON_3 6 12
	Widescreen FALSE
END

/////////////////////////////////////////////////////////////////////

VIG TalkToNFDragon4 MSG-iNF_DRAGON_4
	Widescreen TRUE
    StopC           NF_DRAGON_4
    EngageAndFace   NF_DRAGON_4 P
    RunS            TalkToDragonWarrior
    WanderNotFar    NF_DRAGON_4 6 12
	Widescreen FALSE
END

/////////////////////////////////////////////////////////////////////

VIG TalkToMadFarmer_7 MSG-iMAD_FARMER_7

	IF mj_DEFEAT_GARGOS_2
		Say faf204 farmerf3.bin
	ELSE
		//"We thank you once more, stranger. We owe you our lives."
		Say fa2002 farmerf3.bin
	ENDIF

END

/////////////////////////////////////////////////////////////////////

VIG HideAndrusNote TENSEC && gt_MUST_REMOVE_SCROLL
	
	DeleteObjectsInWorldWithID andrus_note
	Reveal craftbook craftbook
	Remove gt_MUST_REMOVE_SCROLL

END

/////////////////////////////////////////////////////////////////////

VIG MeetAndrus !ce_ANDRUS && gt_PLACED_ANDRUS && INAREA-P-IN_ANDRUS_DOORWAY
	
	WideScreen TRUE
StartRecord

	playmusic Rpg24.WAV

freecam
//camcut matt01
camcut greg1

	// *** START ANDRUS VIGNETTE ***

	ChangeProfileToIdentified Mcitizen_Andrus
	Capture P cM_LOOK_AROUND_EXPECTANT2
	MoveCDir ANDRUS pANDRUS_START

	//"Anyone home?"
	Say Hx0035

	UnDrawSwordRemember
	//"Uncle Andrus?"
	Say Hx0036
	MessagesOff
	QLRemove ql002
	MessagesOn
	QLRemove ql003
camcut andy
	//"...I've been expecting you"
	Say an0001

	//"The night is cold...come in...there's some broth..."
	QuickSay an001b
	Wait 1000
	Capture ANDRUS cM_V5_POINT_BROTH1
	Wait 500
	MoveCDir P pP_SIT_WITH_ANDRUS

	UUComplete ANDRUS
	MoveCDir ANDRUS pANDRUS_LOCKDOOR

	//door swings shut behind player - moved later because of sorting problems.
	RDoorClosed dandrus
	
	
	//"There are strange things in the forest..."
	UUSay
	QuickSay an002b

	UUComplete P
	Capture P cM_V5_KNEEL1			

	//Andrus locks the door
	UUComplete ANDRUS
	Capture ANDRUS cM_PULL_LEVEL
	Wait 250

	//bolt door SFX
	PlaySFXPerson IG_220.WAV ANDRUS

	IDoorLocked dandrus
	UUSay

	//"You knew I was coming...?"
	QuickSay Hx0037

	UUComplete ANDRUS
	MoveCDir ANDRUS pANDRUS_START
	UUSay

	//"...the spirits...enlightened me..."
	Say an0002

	//"You're a Spirit Talker?"
	QuickSay Hx0038

	UUComplete ANDRUS
	Capture ANDRUS cM_V5_KNEEL1
	UUSay

	//"Some would say...I will teach you..."
	Say an0003

	//"...I am willing to learn"
	Say Hx0039

	//"Good... first, the rule"
	Say an0004

	//"What rule?"
	Say Hx0041

	//"...find work and give me gold..."
	Say an0005
	QLAdd ql005 qlt005 qlb005
campan andy02 
setcammoveconstant 5
	Capture ANDRUS cM_V5_STAND1
	UUComplete ANDRUS

	Capture ANDRUS cM_TALK_REFER_RIGHT1
	//"Now take this gift..."
	QuickSay an0007
	Wait 1500
	Capture P cM_V5_STAND1
	UUComplete P
	MoveCDir P pLOOK_AT_EASEL
	UUComplete P
	UUSay

	//player looks confused - (leads into next vignette)
	Capture P cM_TALK_QUESTION1
	UUComplete P

	// *** END ANDRUS VIGNETTE ***

	setcammovenormal
StopRecord
	Add gt_JUST_MET_ANDRUS
	Add ce_ANDRUS
    camcut  P
	AwardEP xp_FIND_ANDRUS
END

/////////////////////////////////////////////////////////////////////

VIG UsePedestal MSG-iPED_ANDRUS

	MoveCDir P pLOOK_AT_EASEL
	UUComplete P

	IF !f_ATTUNED_DREAMS
		IF POS-P-dreams_rune
			Capture P cM_TOSS_GENTLE
			FX_Sprinkle P
			UUComplete P
			DeleteObjectsInBackpackWithID P DREAMS_RUNE
			Add f_ATTUNED_DREAMS
			AwardEP xp_DREAMS
			Wait 1250
		ELSE
			Capture P cM_SHRUG1
		ENDIF
	ENDIF
	IF f_ATTUNED_DREAMS
		SpellPanel DREAMS
	ENDIF

END

/////////////////////////////////////////////////////////////////////

VIG AndrusActions FALSE

	MoveCDir ANDRUS pAN_WORK1
	AddControl ANDRUS DelayControl 1 2
	AddControl ANDRUS DelayControl 2 1
	AddControl ANDRUS MoveCDir pAN_WORK2
	AddControl ANDRUS MoveCDir pAN_WORK3
	AddControl ANDRUS MoveCDir pAN_WORK4
	AddControl ANDRUS Capture cM_LOOK_AROUND_HANDS_HIPS1
	AddControl ANDRUS Capture cM_LOOK_AROUND_HANDS_HIPS2
	AddControl ANDRUS Capture cM_RUB_HANDS2_BETTER
	AddControl ANDRUS Capture cM_SHRUG1
	SequenceRandomlySelects ANDRUS
	SwitchOnSightOfPlayer ANDRUS LookAtTurnFollow P

END

/////////////////////////////////////////////////////////////////////

VIG TalkToAndrus MSG-iANDRUS || gt_JUST_MET_ANDRUS

	WideScreen TRUE
	UnDrawSwordRemember

	Remove gt_JUST_MET_ANDRUS

	IF !mj_SLEPT_AT_ANDRUS
		//"Ah, there is more you wish to know? Or perhaps you are tired..."
		Say an007c
		EngageAndFace P Andrus
	ELSE
		//"Ah, I trust you have been busy on my errand?"
		QuickSay an007b
		EngageAndFace P Andrus
		UUSay
	ENDIF

	ResetChoice
	WHILE !MenuExit
		ClearChoices

		// *** SETUP MENU ***

		//Books Of Magic
		AddChoice 1 txt900

		IF gt_ANDRUS_GIVEN_RUNE
			//The Rune
			AddChoice 2 txt902
		ELSE
			//Runes
			AddChoice 2 txt901
		ENDIF

		//Hexes
		IF co_THEHEX
			AddChoice 3 tx0025
		ENDIF

		IF ce_RAAL
			IF gt_ANDRUS_NAMED_RAAL
				//Raal
				AddChoice 4 tx0032
			ELSE
				//The man outside
				AddChoice 4 tx0043
			ENDIF
		ENDIF

		IF !mj_SLEPT_AT_ANDRUS
			//Sleep
			AddChoice 5 txt906
		ELSE
			IF mj_HEX_COMPASS
				//Magic Compass
				AddChoice 6 txt908
			ELSE
				IF AFFORD-1
					//Give Andrus gold
					AddChoice 6 txt907
				ENDIF
			ENDIF
		ENDIF

		IF POS-P-trinkets_book
			IF gt_ANDRUS_NAMED_BOOK
				//Book Of Trinkets
				AddChoice 7 txt910
			ELSE
				//Golden Grimoire
				AddChoice 7 txt909
			ENDIF
		ENDIF

		//Leave
		AddChoice 0 tx0003

		// *** DISPLAY THE MENU ***
		GetChoice ANDRUS

		// *** DEAL WITH THE CHOICE ***
		SWITCH CHOICE
			CASE 1
				//Books Of Magic

				//"Most books...require a special place...Hexes..."
				Say an0009

				Add co_THEHEX

			CASE 2
				//The Rune -or- Runes
				IF !gt_ANDRUS_GIVEN_RUNE

					//"Here. The spirits of the tower entrusted me with this."
					QuickSay an0011
					Wait 1000

					Capture ANDRUS cM_TOSS_GENTLE
					Capture P cM_OBJ_ACCEPT_1H1
					UUSay

					Add gt_ANDRUS_GIVEN_RUNE
					UUComplete ANDRUS
					AwardOb P dreams_rune "dreams-rune"
					DeleteObjectsInBackpackWithID ANDRUS dreams_rune
				ENDIF

				//"It is a rune from the scales of Kinkathra..."
				Say an011a

			CASE 3
				//Hexes

				//"A Hex is what the Warlocks called their homes..."
				Say an0010

			CASE 4
				//Raal -or- The man outside

				//"A Raal...a demon...Be on your guard..."
				Say an0016

				Add gt_ANDRUS_NAMED_RAAL
				ChangeProfileToIdentified Mdemon_Raal

			CASE 5
				//Sleep

				// *** Cosy bedtime scene ***
				Widescreen TRUE
				
				//"Yes, it is time to retire. The beds are this way..."
				QuickSay an0012
				Wait 3000
				MoveCDir ANDRUS pANDRUS_A_BED
				Wait 2500

				MoveCDir P pANDRUS_P_BED
				UUSay

				RunS PalFadeBLACK
				UUComplete P
				RemoveC ANDRUS
				PlaceC ANDRUS pAN_WORK1
				HealCharacter P
				//Capture P cM_V5_GET_OFF_BED1
				RunS SetUpDoors-MetAndrus
				Wait 1500
				Widescreen FALSE

				// Next day message
				MessagePumpLongGreen 223

				RunS PalFadeRPG

				UUComplete P

				// *** End of cosy bedtime scene ***

				Add mj_SLEPT_AT_ANDRUS
				AwardEP xp_SLEPT_AT_ANDRUS
				SetChoiceToExit
				UUFade

				//it's now too late to kill brigands if you haven't done so...

				IF !gt_KEEP_SSB1_QUEST
					MessagesOff
					QLDelete ql004
					MessagesOn
				ENDIF

				IF gt_PLACED_NF_BRIG
					Remove gt_PLACED_NF_BRIG
					KillC  NF_BRIG_1
					KillC  NF_BRIG_2
					KillC  NF_BRIG_3
				ENDIF
				
			CASE 6
				//Give Andrus gold -and- Magic Compass

				IF !mj_HEX_COMPASS && !AFFORD-200
					//"You do not yet have enough gold. Come back..."
					Say an0017
				ELSE
					IF !mj_HEX_COMPASS

						Capture P cM_TOSS_GENTLE
						Capture ANDRUS cM_OBJ_ACCEPT_1H1
						Gold- P 200
						Wait 500

						//"Ah. You have shown that you are willing...you can be trusted now with this."
						Say an0018

						UUComplete ANDRUS
						UUComplete P
						Capture ANDRUS cM_TOSS_GENTLE
						Capture P cM_OBJ_ACCEPT_1H2
						UUComplete ANDRUS

						AwardOb P hcpass "hex-compass"
						Add mj_HEX_COMPASS
						AwardEP xp_HEX_COMPASS
						Add co_THEHEX
						Add co_TEMPLE_OF_SHADOWS

						RunS SetUpDoors-AwardedHexCompass
						QLRemove ql005
					ENDIF
					//"This is...another gift from the spirits...the true guide to the ancient Hexes..."
					Say an0019
					//"...look to the west...further training...Temple Of Shadows...library there."
					Say an0030
					IF !gt_QL012 && !gt_QL013
						Add gt_QL012
						QLAdd ql012 qlt012 qlb012
					ENDIF

				ENDIF

			CASE 7
				//Book Of Trinkets -or- Golden Grimoire

				//"Hmm. The book is old...a tome of potent and useful magic..."
				Say an026b

				IF !gt_ANDRUS_NAMED_BOOK
					IdentifyObject trinkets_book
					Add gt_ANDRUS_NAMED_BOOK
				ENDIF

		ENDSWITCH
	ENDWHILE
	
	// *** END CONVERSATION WITH ANDRUS ***

	IF mj_SLEPT_AT_ANDRUS
		RunS AndrusActions
	ENDIF

	WideScreen FALSE
NormalCam
//	DrawSwordRemember

END

/////////////////////////////////////////////////////////////////////

VIG Andrus_v_Tamaran ONESEC && gt_PLACED_ANDRUS_DYING && !f_ANDRUS_DEAD

	SetHP NF_HEX_SEEKER 150
	SetHP ANDRUS 1000

END

/////////////////////////////////////////////////////////////////////

VIG DeathOfAndrus HALFSEC && !f_ANDRUS_DEAD && mj_BEEN_TO_HEX && (INAREA-P-NEAR_ANDRUS_BODY || DISTFROM-P-ANDRUS-15 || MSG-iANDRUS)

	CueSnow 0 10

	Add f_ANDRUS_DEAD

	Widescreen TRUE
	playmusic rpg26.wav
	SetHP NF_HEX_SEEKER 150
	ChangeProfileToNotDestiny mcitizen_andrus

	camcut pos2000
	setcammoveconstant 5
	campan pos3000

	// *** START OF DEATH OF ANDRUS VIGNETTE ***


	//"Uncle? Uncle Andrus!"
	SetWalkType P run
	Engage P ANDRUS 400
	Say Hx0238

	Wait 500

	SetHP ANDRUS 1

	UUComplete P

	WHILE !ISDEAD-ANDRUS
		Wait 500
	ENDWHILE

	Face P NF_HEX_SEEKER

	//"HexMaster...Now, you are mine."
	Say xs0001 HEXSEEKR.BIN

	//"You killed my uncle."
	Capture P cM_TALK_THREATEN1
	Say Hx242b
	//"Indeed. I am Tamaran..."
	Capture NF_HEX_SEEKER cM_TALK_REFER_SELF2
	Say xs0003 HEXSEEKR.BIN

	SetHP NF_HEX_SEEKER 150
	AttackDemo2 NF_HEX_SEEKER
			
	// *** END OF DEATH OF ANDRUS VIGNETTE ***
camcut p
setcammovenormal
	Widescreen FALSE

END

/////////////////////////////////////////////////////////////////////

VIG DRAndrus MSG-DR_ANDRUS

	IF !gt_PLAYED_DR_ANDRUS

		Widescreen TRUE

		Add gt_PLAYED_DR_ANDRUS

		//"You must go with great care...one of the Hex Seekers...follow Harbinger...undo his mistake..."
		Say An0064

		ResetChoice
		WHILE !MenuExit
			ClearChoices

			// *** SETUP MENU ***

			//Harbinger's Mistake
			AddChoice 1 txt400

			//Hex Seekers
			AddChoice 2 txt401

			//Leave
			AddChoice 0 tx0003

			// *** DISPLAY THE MENU ***

			GetChoice ANDRUS

			// *** DEAL WITH THE CHOICE ***
			SWITCH CHOICE
				CASE 1
					//Harbinger's Mistake

					//"Harbinger thought he had destroyed the Revenants...seek out their minions - look to Shadowguard."
					Say an064b

				CASE 2
					//Hex Seekers

					//"...servants of the League of Six...once warlocks, corrupted..."
					Say an064a

				CASE 0
					//Leave

					//"Don't grieve... I go to the Well..."
					Say an0065
			ENDSWITCH
		ENDWHILE
		AwardEP xp_ANDRUS_FAREWELL

		Widescreen FALSE
	ELSE
		Runs DR_GENERIC_FAIL
	ENDIF
END

/////////////////////////////////////////////////////////////////////

VIG MeetNFRaal HALFSEC && gt_PLACED_RAAL && !ce_RAAL && INAREA-P-NEAR_NF_RAAL

	Add ce_RAAL

	Widescreen TRUE
	playmusic rpg26.wav
	
	PlaySFXPerson Raal1.wav RAAL
freecam
	// *** RAAL VIGNETTE START ***

	MoveCDir		P			pP_MEETING_RAAL 
	AddControl		P			LookAtTurn		RAAL 
setcammoveconstant 10
campan			pos01
	Wait			1000
	Capture			RAAL		cM_V4_RAAL_SNIFF_GROUND2_BETTER

	Wait 1250

	//"Does something ail you?"
	QuickSay		Hx028j 

	REM				*** Raal attempts mind control ***
	
	AddControl		RAAL		LookAtTurn		P 

	UUComplete		RAAL 
	//Capture			RAAL		cM_V4_RAAL_CAST_SPELL1 
	Capture			RAAL		cM_THRUST_HANDF2
	StopSFX	Raal1.wav
	PlaySFXPerson	Raal2.wav RAAL
	FX_Sprinkle		RAAL
	Wait 500

	Capture			P			cM_V4_DROP_TO_KNEES2 
camcut pos02
	UUSay
	//"I am no one. You do not see me."
	Say				ra0001		RAAL

	//UUComplete		RAAL
	Capture			RAAL		cM_THRUST_HANDF2
	//Capture			RAAL		cM_V4_RAAL_CAST_SPELL2_SHORT 
	StopSFX	Raal2.wav
	PlaySFXPerson	Raal9.wav RAAL
	FX_Sprinkle		RAAL

	//"Of course I...what are you doing?"
	QuickSay				Hx0030 

	Capture			P			cM_TALK_QUESTION1
	UUSay

	//"I was not here."
	Say				ra0002		RAAL 
	//"Duh?"
	QuickSay		Hx0029
	
	UUComplete		RAAL 

	MoveCDir		RAAL				D_RAAL1	RUN
	AddControl		RAAL	MoveCDir	D_RAAL2	RUN
	StopSFX			Raal9.wav
	PlaySFXPerson	Raal1.wav RAAL

	UUComplete 		P
	MoveCDir		P	D_PLAY1
	AddControl		P	LookAtFollow	RAAL
	
	Add	gt_D_RAAL_WALKING

	UUSay
	SetCamMoveNormal
	NormalCam
	camcut			P
	
	Widescreen FALSE
END

/////////////////////////////////////////////////////////////////////	

VIG D_RaalArrived HALFSEC && gt_D_RAAL_WALKING && CC-RAAL

	Remove gt_D_RAAL_WALKING
	//FX_GreenFire RAAL pants
	KillC RAAL

END

/////////////////////////////////////////////////////////////////////

VIG EnterEmptyShack !ce_ANDRUS && !f_PLAYED_INTRO_PUB_VIG && !gt_PLACED_RAAL && INAREA-P-ANDRUS-SHACK

	RunS ResetBrigandControllers

	WideScreen TRUE

	freecam
	camcut matey

	Capture P cM_LOOK_AROUND_EXPECTANT2

	//"Anyone home?"
	Say Hx0035

	Wait 2500

	setcammovenormal
NormalCam
	camcut P

	Widescreen FALSE

	Add		gt_PLACED_RAAL
	PlaceC	RAAL pRAAL_START
END

/////////////////////////////////////////////////////////////////////

// THE NORTH FOREST BRIGAND CAMP

/////////////////////////////////////////////////////////////////////

VIG ResetBrigandControllers FALSE

	IF gt_PLACED_NF_BRIG
		RemoveC NF_BRIG_1
		RemoveC NF_BRIG_2
		RemoveC NF_BRIG_3
		PlaceC NF_BRIG_1 pNF_BRIG_1
		PlaceC NF_BRIG_2 pNF_BRIG_2
		PlaceC NF_BRIG_3 pNF_BRIG_3
	ELSE
		Add gt_PLACED_NF_BRIG
	ENDIF

	Remove gt_NFB_RUN_FOR_HELP
	Remove gt_NFB_ATTACK

	LookAtTurn NF_BRIG_1 NF_BRIG_2
	AddControl NF_BRIG_1 Capture cM_TALK_AGREE1
	AddControl NF_BRIG_1 Capture cM_TALK_AGREE2
	AddControl NF_BRIG_1 Capture cM_TALK_AGREE3
	AddControl NF_BRIG_1 MoveC pNF_BRIG_1
	SequenceRandomlySelects NF_BRIG_1

	LookAtTurn NF_BRIG_2 NF_BRIG_1
	AddControl NF_BRIG_2 Capture cM_TALK_AGREE1
	AddControl NF_BRIG_2 Capture cM_TALK_AGREE2
	AddControl NF_BRIG_2 Capture cM_TALK_AGREE3
	AddControl NF_BRIG_2 MoveC pNF_BRIG_2
	SequenceRandomlySelects NF_BRIG_2

	Filter     NF_BRIG_3 FailCompletes LookAtTurn P
	AddControl NF_BRIG_3 Capture cM_V6_LOOK_AROUND2_BETTER
	AddControl NF_BRIG_3 MoveC pNF_BRIG_3
	SequenceRandomlySelects NF_BRIG_3

END

/////////////////////////////////////////////////////////////////////

VIG NFBRigRunsForHelp ONESEC && (INAREA-P-BRIG_WALK_AREA || DAMAGED-NF_BRIG_3) && !gt_NFB_RUN_FOR_HELP && !gt_NFB_ATTACK && !ISDEAD-NF_BRIG_3

	ClearDamaged NF_BRIG_3
	MoveC NF_BRIG_3 pNF_BRIG_3_CAMP run
	Add gt_NFB_RUN_FOR_HELP

END

/////////////////////////////////////////////////////////////////////

VIG NFBrigLetsGo ONESEC && !gt_NFB_ATTACK && (CC-NF_BRIG_3 || INAREA-P-BRIG_CAMP || DAMAGED-NF_BRIG_1 || DAMAGED-NF_BRIG_2)

	Add gt_NFB_ATTACK

	IF !ISDEAD-NF_BRIG_3
		SetWalkType NF_BRIG_3 walk
		GiveSightOfPlayerTo		NF_BRIG_3
		MoveC					NF_BRIG_3	pNF_BRIG_3_CAMP
		AddControl				NF_BRIG_3	Capture cM_V6_LOOK_AROUND2_BETTER
		SequenceRandomlySelects NF_BRIG_3
		SwitchOnSightOfPlayer	NF_BRIG_3	AttackDemo2
		PushControl				NF_BRIG_3
		Filter					NF_BRIG_3	FailCompletes	Engage P 1000
		AddControl				NF_BRIG_3	PopControl
	ENDIF

	GiveSightOfPlayerTo		NF_BRIG_1
	MoveC					NF_BRIG_1	pNF_BRIG_1
	AddControl				NF_BRIG_1	Capture cM_V6_LOOK_AROUND2_BETTER
	SequenceRandomlySelects NF_BRIG_1
	SwitchOnSightOfPlayer	NF_BRIG_1	AttackDemo2
	PushControl				NF_BRIG_1
	Filter					NF_BRIG_1	FailCompletes	Engage P 1000
	AddControl				NF_BRIG_1	PopControl

	GiveSightOfPlayerTo		NF_BRIG_2
	MoveC					NF_BRIG_2	pNF_BRIG_2
	AddControl				NF_BRIG_2	Capture cM_V6_LOOK_AROUND2_BETTER
	SequenceRandomlySelects NF_BRIG_2
	SwitchOnSightOfPlayer	NF_BRIG_2	AttackDemo2
	PushControl				NF_BRIG_2
	Filter					NF_BRIG_2	FailCompletes	Engage P 1000
	AddControl				NF_BRIG_2	PopControl


END

/////////////////////////////////////////////////////////////////////

VIG DRHexSeeker MSG-DR_NF_HEX_SEEKER

	IF !gt_PLAYED_DR_NF_HEX_SEEKER

		Add gt_PLAYED_DR_NF_HEX_SEEKER

		Widescreen TRUE

		Engage P NF_HEX_SEEKER

		Say hs0001 HEXSEEKR.BIN

		ResetChoice
		WHILE !MenuExit
			ClearChoices

			AddChoice 1 txhs01
			AddChoice 2 txhs02
			AddChoice 3 txhs03
			AddChoice 0 tx0003

			GetChoice NF_HEX_SEEKER

			SWITCH Choice
				CASE 1
					Say hs0002 HEXSEEKR.BIN
				CASE 2
					Say hs0003 HEXSEEKR.BIN
					ChangeProfileToIdentified Mdemon_Tamaran
				CASE 3
					Say hs003a HEXSEEKR.BIN
			ENDSWITCH
		ENDWHILE

		Say hs0004 HEXSEEKR.BIN

		IF POS-P-stake
			//Say dr0063 PC1.BIN
			UUComplete P
			Capture P cM_STAKE_1
			Add f_TAMARAN_DEAD
			wait 1000
			FX_HexStake NF_HEX_SEEKER
			AwardEP xp_TAMARAN_DEAD
			UUComplete P

			DeleteObjectsInBackpackWithID P stake 1
			Wait 1000

		ELSE
			//Say dr0064 PC1.BIN
			Say hs0005 HEXSEEKR.BIN
		ENDIF

		Widescreen FALSE

	ELSE
		Runs DR_GENERIC_FAIL
	ENDIF

END

/////////////////////////////////////////////////////////////////////
