/////////////////////////////////////////////////////////////////////
// SHADOW.S
/////////////////////////////////////////////////////////////////////

SETUP

	IF !gt_PLACED_ARADDHOM
		Add gt_PLACED_ARADDHOM
		PlaceC ARADDHOM pARAD_START

		Filter			ARADDHOM Timeout 5 Wander
		AddControl		ARADDHOM DelayControl 2 3
		SequenceLoops	ARADDHOM
	ENDIF

	ChangeProfileToNotDestiny Ssoldier_AradDhom

END

VIG TempSetup FALSE

	SetWeather 0 0 0 0 0 0 0 0

	AddBigFire 5165 47091

	CachePortrait ARADDHOM.BIN
	CachePortrait PC1.BIN
END

/////////////////////////////////////////////////////////////////////

VIG AradDhomDead ONESEC && !gt_ARADDHOM_DEAD && ISDEAD-ARADDHOM

	Add gt_ARADDHOM_DEAD
	Add gt_SKIFF_CHART_TRADED

END

/////////////////////////////////////////////////////////////////////

VIG TalkToAradDhom MSG-iARADDHOM

	Widescreen TRUE
	EngageAndFace P ARADDHOM

	IF !ce_ARADDHOM
		//"And who in Hades would you be?"
		Say ad0001 ARADDHOM.BIN
		//"A traveller. Just passing through."
		Say Hx0309
		//"Traveller eh? Well I'm the law around here, traveller. Arad Dhom's my name, but you can call me Sheriff."
		Say ad0002 ARADDHOM.BIN

		Add ce_ARADDHOM
		Add co_ARADDHOM
		ChangeProfileToIdentified Ssoldier_AradDhom
	ENDIF

	ResetChoice
	WHILE !MenuExit
		ClearChoices

		IF co_LORDBANE
			//Lord Bane
			AddChoice 1 tx0111
		ENDIF

		IF co_THEGUILD
			//The Guild
			AddChoice 2 tx0097
		ENDIF

		IF co_ASH
			//Ash
			AddChoice 3 tx0106
		ENDIF

		IF ce_SKIFF
			//Skiff
			AddChoice 4 tx0099
		ENDIF

		IF co_SEACHART
			//Skiff's chart
			AddChoice 5 tx9117
		ENDIF

		//Leave
		AddChoice 0 tx0003

		GetChoice ARADDHOM ARADDHOM.BIN

		SWITCH Choice
			CASE 1
				//Lord Bane

				IF mj_RESCUE_BANE
					//"...a twisted man...keep away from him, and his kind."
					Say ad0008 ARADDHOM.BIN
				ELSE
					//"Bane left for the eastern Fens...hope he remains there..."
					Say ad008a ARADDHOM.BIN
				ENDIF

			CASE 2
				//The Guild

				//"Guild boy, what sort of guild? If it's the Fisherman's Guild you mean...I shut it down..."
				Say ad0009 ARADDHOM.BIN
				//"No...a Guild of a more private nature."
				Say Hx0312
				//"There's no Guild like that...in my town. Thardolin maybe..."
				Say ad0010 ARADDHOM.BIN

			CASE 3
				//Ash

				//"Rumours abound..."
				Say ad0012 ARADDHOM.BIN

			CASE 4
				//Skiff

				//"...bitter man - and a bad loser..."
				Say ad0013 ARADDHOM.BIN

			CASE 5
				//Skiff's chart

				//"...you're too late...I traded it...from Thardolin...Empress's own guard...on his way to charter that old fool's boat..."
				Say ad0011 ARADDHOM.BIN

				Add gt_SKIFF_CHART_TRADED

		ENDSWITCH
	ENDWHILE

	//"Be vigilant, you hear? I'll be watching you."
	Say ad0014 ARADDHOM.BIN

	Widescreen FALSE

	Filter			ARADDHOM Timeout 5 Wander
	AddControl		ARADDHOM DelayControl 2 3
	SequenceLoops	ARADDHOM

END

/////////////////////////////////////////////////////////////////////
