/////////////////////////////////////////////////////////////////////
// BLOOD.S
/////////////////////////////////////////////////////////////////////

SETUP

	IF !mj_DEFEAT_LIGHTSTEALER

		Add gt_JAKE_GONE

		RemoveC P
		PlaceC P p1_P
		camcut P

		IF DEMO_BLOOD_A

			PlaceC BLAND_BKIN_A1	p3_A1
			PlaceC BLAND_BKIN_A2	p3_A2
			PlaceC BLAND_BKIN_A3	p3_A3
			PlaceC BLAND_BKIN_C3	p3_C3
			PlaceC BLAND_BKIN_D2	p3_D2
			PlaceC BANE			p3_BANE
			PlaceC LAEN				p3_LAEN

			Add gt_BLOOD_INTRO 
			Add gt_BLOOD_DEAD_01 
			Add gt_BLOOD_DEAD_03

		ELSE
			IF DEMO_BLOOD_B

				PlaceC LIGHTSTEALER p7_LS
				PlaceC BANE p7_BANE
				PlaceC BLOOD_VAMP_13 p7_13
				PlaceC BLOOD_VAMP_14 p7_14
				PlaceC BLOOD_VAMP_15 p7_15
				RemoveC P
				PlaceC P			p6_P
				camcut P

				Add gt_BLOOD_INTRO 
				Add gt_BLOOD_DEAD_07
				Add gt_BANE_v_LIGHTSTEALER 
				Set hp_LIGHTSTEALER	100
				SetHP LIGHTSTEALER 99
				IDoorClosed cof_1
				IDoorClosed cof_2
				IDoorClosed cof_3

			ELSE
				IF !gt_BLOOD_CHARS
					Add gt_BLOOD_CHARS

					ResetStats BLAND_BKIN_A1
					ResetStats BLAND_BKIN_A2
					ResetStats BLAND_BKIN_A3
					ResetStats BLAND_BKIN_C3
					ResetStats BLAND_BKIN_D2

					PlaceC BANE p1_BANE
					PlaceC LAEN p1_LAEN
					PlaceC BLAND_BKIN_A1 p1_A1
					PlaceC BLAND_BKIN_A2 p1_A2
					PlaceC BLAND_BKIN_A3 p1_A3
					PlaceC BLAND_BKIN_C3 p1_C2
					PlaceC BLAND_BKIN_D2 p1_D2

					IDoorOpen dBLOOD
					IDoorLocked dBLOOD_TOWER
				ENDIF
			ENDIF
		ENDIF

	ELSE
		IF gt_BLOOD_CHARS
			Remove gt_BLOOD_CHARS

			RemoveC BANE
			RemoveC BLAND_BKIN_A1
			RemoveC BLAND_BKIN_A2
			RemoveC BLAND_BKIN_A3
			RemoveC BLAND_BKIN_C3
			RemoveC BLAND_BKIN_D2
		ENDIF
	ENDIF

	Add gg_FROMSETUP
END

VIG TempSetup FALSE

	Set	gd_WEATHER_TYPE	0
	Set gd_WIND_TYPE	1
    RunS CueWeather

	IF !gg_FROMSETUP
		playloopedmusic rpg15.wav
	ENDIF

	CachePortrait LORDBANE.BIN
	CachePortrait LAENCHNT.BIN
	CachePortrait PC2.BIN
	CachePortrait LGHTSTRL.BIN

END

/////////////////////////////////////////////////////////////////////

VIG RemoveAFlag gg_FROMSETUP
	Remove gg_FROMSETUP
END

/////////////////////////////////////////////////////////////////////

VIG HorribleBodgeDemoA ONESEC && DEMO_BLOOD_A

	Remove DEMO_BLOOD_A

	Message "The characters may be somewhere else after that last battle" 10

END

/////////////////////////////////////////////////////////////////////

VIG HorribleBodgeDemoB ONESEC && DEMO_BLOOD_B

	Remove DEMO_BLOOD_B

	MeleeAttackBLands LIGHTSTEALER
	MeleeAttackBLands BANE
	MeleeAttackBLands BLOOD_VAMP_13
	MeleeAttackBLands BLOOD_VAMP_14
	MeleeAttackBLands BLOOD_VAMP_15

	Message "Vignette is triggered when Lord Bane is killed" 10

END

/////////////////////////////////////////////////////////////////////

VIG EnterCity !gt_BLOOD_INTRO && !mj_DEFEAT_LIGHTSTEALER

	Add gt_BLOOD_INTRO

	SamplesOff
	PlaceC	BLOOD_VAMP_x7 p5_07
	PlaceC	BLOOD_VAMP_x8 p5_08
	PlaceC	BLOOD_VAMP_x9 p5_09
	PlaceC	BLOOD_VAMP_x0 p5_10
	SetHP BLOOD_VAMP_x7 10
	SetHP BLOOD_VAMP_x8 10
	SetHP BLOOD_VAMP_x9 10
	SetHP BLOOD_VAMP_x0 10
	NormalDamageNA BLOOD_VAMP_x7 30
	NormalDamageNA BLOOD_VAMP_x8 15
	NormalDamageNA BLOOD_VAMP_x9 50
	NormalDamageNA BLOOD_VAMP_x0 25
	SamplesOn

freecam
	Widescreen TRUE

	RunS QPalFadeRPG
camcut pos01
setcammoveconstant 1
campan pos02

	Engage LAEN BANE 500
	UUComplete LAEN

	//"Look upon this place..."
	Say lb0034

	Capture BANE cM_HOLD_OBJ_ALOFT1
	//"For the blood, and the white moon!"
	QuickSay lb0027

	Capture LAEN cM_HOLD_OBJ_ALOFT1

	//"For the blood, and the white moon!"
	//QuickSay km0001 CREDO.BIN
	Capture BLAND_BKIN_A1 cM_HOLD_OBJ_ALOFT1
	Wait 25
	Capture BLAND_BKIN_C3 cM_HOLD_OBJ_ALOFT1
	Wait 5
	Capture BLAND_BKIN_D2 cM_HOLD_OBJ_ALOFT1
	Wait 15
	Capture BLAND_BKIN_A2 cM_HOLD_OBJ_ALOFT1
	Wait 5
	Capture BLAND_BKIN_A3 cM_HOLD_OBJ_ALOFT1

	UUsay
	UUComplete LAEN

	LookAtTurn LAEN P

	//"Let us make light of foot..."
	Say da0043

	LookAtTurn P LAEN

	//"After you..."
	Say Hx321a

	MoveCDir BANE p2_BANE
	MoveCDir LAEN p2_LAEN
	
Wait 500
camcut pos04
setcammoveconstant 10
campan pos05
	MoveCDir P p2_P
	Wait 250
	MoveCDir BLAND_BKIN_A1 p2_A1
	MoveCDir BLAND_BKIN_A2 p2_A2
	MoveCDir BLAND_BKIN_A3 p2_A3
	Wait 250
	MoveCDir BLAND_BKIN_C3 p2_C3
	MoveCDir BLAND_BKIN_D2 p2_D2

	//"Ha ha ha"
	Say da043b

	Wait 5000

	//"Where is everybody?"
	Say Hx321b

	//"...not sure...we should scout..."
	Say da043c

	UUComplete BANE
	LookAtTurn BANE BLAND_BKIN_A2

	//"You five...look around...be careful."
	Say lb0044

	MoveCDir BLAND_BKIN_A1 p3_A1
	Wait 250
	MoveCDir BLAND_BKIN_A2 p3_A2
	MoveCDir BLAND_BKIN_A3 p3_A3
	Wait 250
	MoveCDir BLAND_BKIN_C3 p3_C3
	MoveCDir BLAND_BKIN_D2 p3_D2
	Wait 500
setcammoveconstant 8
camnlock 355
campan pos06	
	//MoveCDir BANE p3_BANE
	EngagePoint BANE p3_BANE 150
	Wait 1000
	MoveCDir LAEN p3_LAEN
	MoveCDir P p3_P

	UUComplete BANE

	LookAtTurn P BANE
	LookAtTurn LAEN BANE

	Wait 2000

	Capture BANE cM_HEWING_STONE Notifies 3 245 BaneStrikesDoor 500 BaneStrikesDoor 800 BaneStrikesDoor

	WHILE !CC-BANE
		Wait 25
	ENDWHILE
	
	PlaceC BLOOD_VAMP_01 p3_01
	PlaceC BLOOD_VAMP_02 p3_02
	PlaceC BLOOD_VAMP_03 p3_03
	PlaceC BLOOD_VAMP_04 p3_04
	PlaceC BLOOD_VAMP_05 p3_05
	PlaceC BLOOD_VAMP_06 p3_06
	PlaceC BLOOD_VAMP_07 p3_07
	PlaceC BLOOD_VAMP_08 p3_08
	PlaceC BLOOD_VAMP_09 p3_09
	PlaceC BLOOD_VAMP_10 p3_10

	//these are the only ones that will be visible 
	FX_GreenFire BLOOD_VAMP_01
	FX_GreenFire BLOOD_VAMP_03
	FX_GreenFire BLOOD_VAMP_05
	FX_GreenFire BLOOD_VAMP_06

	IDoorLocked dBLOOD

	LookAtTurn LAEN P

	//"It's an ambush! Regroup at the gates!"
	//Say km0002 CREDO.BIN

	MoveC LAEN p2_LAEN
camcut p
setcammovenormal
NormalCam
	//"Warlock...Run...secure our way out!"
	QuickSay da043d

	QLAdd ql026 qlt026 qlb026

	Wait 2500
	playloopedmusic rpg15.wav

	MeleeAttackBLands LAEN
	MeleeAttackBLands	BLAND_BKIN_A1
	MeleeAttackBLands	BLAND_BKIN_A2
	MeleeAttackBLands	BLAND_BKIN_A3
	MeleeAttackBLands	BLAND_BKIN_C3
	MeleeAttackBLands	BLAND_BKIN_D2

	UUSay

	Capture BANE cM_HEWING_STONE Notifies 3 245 BaneStrikesDoor 500 BaneStrikesDoor 800 BaneStrikesDoor
	AddControl BANE MoveCDir p3_BANE
	SequenceLoops BANE

	MoveC P p1_P run

	MeleeAttackBLands BLOOD_VAMP_01
	MeleeAttackBLands BLOOD_VAMP_02
	MeleeAttackBLands BLOOD_VAMP_03
	MeleeAttackBLands BLOOD_VAMP_04
	MeleeAttackBLands BLOOD_VAMP_05
	MeleeAttackBLands BLOOD_VAMP_06
	MeleeAttackBLands BLOOD_VAMP_07
	MeleeAttackBLands BLOOD_VAMP_08
	MeleeAttackBLands BLOOD_VAMP_09
	MeleeAttackBLands BLOOD_VAMP_10

	Wait 7500

	Widescreen FALSE

END

/////////////////////////////////////////////////////////////////////

VIG TalkToBaneInCombat MSG-iBANE

	//"For the Blood and the White Moon!"
	QuickSay lb0027

END

/////////////////////////////////////////////////////////////////////

VIG TalkToBKInCombat1 MSG-iBLAND_BKIN_A2 || MSG-iBLAND_BKIN_C3 || MSG-iBLAND_BKIN_D2

	//"For the White Moon!"
	QuickSay bk0003 CREDO.BIN

END

/////////////////////////////////////////////////////////////////////

VIG TalkToBKInCombat2 MSG-iBLAND_BKIN_A1 || MSG-iBLAND_BKIN_A3

	IF LANG-French || LANG-Dutch || LANG-German
		//"For the White Moon!"
		QuickSay bk0003 BKINMAN3.BIN
	ELSE
		//"For Tortalaran and the Blood!"
		QuickSay bk0008 BKINMAN3.BIN
	ENDIF

END

/////////////////////////////////////////////////////////////////////

VIG TalkToLaenInCombat MSG-iLAEN

	//"Ha Ha Ha!"
	QuickSay da043b

END

/////////////////////////////////////////////////////////////////////

VIG BaneStrikesDoor FALSE

	// clang SFX
	PlaySFXPerson ig_301.WAV BANE

END

/////////////////////////////////////////////////////////////////////

VIG BaneBreaksDoor FALSE

	// clang SFX
	PlaySFXPerson ig_301.WAV BANE
	PlaySFXPerson IG_295.WAV BANE

	IDoorClosed dBLOOD_TOWER
	RDoorOpen dBLOOD_TOWER

END

/////////////////////////////////////////////////////////////////////

VIG DeadBloodkinA1 FIVESEC && gt_BLOOD_INTRO && !gt_BLOOD_DEAD_A1 && ISDEAD-BLAND_BKIN_A1 && ISDEAD-BLAND_BKIN_A2

	Add gt_BLOOD_DEAD_A1

	EngagePoint BLOOD_VAMP_01 p1_BANE 1234
	AddControl	BLOOD_VAMP_01 MeleeAttackBLands
	EngagePoint BLOOD_VAMP_02 p1_BANE 1234
	AddControl	BLOOD_VAMP_02 MeleeAttackBLands

END

/////////////////////////////////////////////////////////////////////

VIG DeadBloodkinA3 FIVESEC && gt_BLOOD_INTRO && !gt_BLOOD_DEAD_A3 && ISDEAD-BLAND_BKIN_A3 && ISDEAD-BLAND_BKIN_C3

	Add gt_BLOOD_DEAD_A3

	EngagePoint BLOOD_VAMP_03 p1_BANE 1234
	AddControl	BLOOD_VAMP_03 MeleeAttackBLands
	EngagePoint BLOOD_VAMP_04 p1_BANE 1234
	AddControl	BLOOD_VAMP_04 MeleeAttackBLands

END

/////////////////////////////////////////////////////////////////////

VIG DeadVampire01 FIVESEC && gt_BLOOD_INTRO && !gt_BLOOD_DEAD_01 && ISDEAD-BLOOD_VAMP_01 && ISDEAD-BLOOD_VAMP_02

	Add gt_BLOOD_DEAD_01

	IF !gt_BANE_v_LIGHTSTEALER
		EngagePoint BLAND_BKIN_A1 p1_BANE 1234
		AddControl	BLAND_BKIN_A1 MeleeAttackBLands
		EngagePoint BLAND_BKIN_A2 p1_BANE 1234
		AddControl	BLAND_BKIN_A2 MeleeAttackBLands
	ELSE
		EngagePoint BLAND_BKIN_A1 p3_LAEN 550
		EngagePoint BLAND_BKIN_A2 p3_LAEN 600
	ENDIF

END

/////////////////////////////////////////////////////////////////////

VIG DeadVampire03 FIVESEC && gt_BLOOD_INTRO && !gt_BLOOD_DEAD_03 && ISDEAD-BLOOD_VAMP_03 && ISDEAD-BLOOD_VAMP_04

	Add gt_BLOOD_DEAD_03

	IF !gt_BANE_v_LIGHTSTEALER
		EngagePoint BLAND_BKIN_A3 p1_BANE 1234
		AddControl	BLAND_BKIN_A3 MeleeAttackBLands
		EngagePoint BLAND_BKIN_C3 p1_BANE 1234
		AddControl	BLAND_BKIN_C3 MeleeAttackBLands
	ELSE
		EngagePoint BLAND_BKIN_A3 p3_LAEN 650
		EngagePoint BLAND_BKIN_C3 p3_LAEN 700
	ENDIF

END

/////////////////////////////////////////////////////////////////////

VIG DeadVampire05 FIVESEC && gt_BLOOD_INTRO && !gt_BLOOD_DEAD_05 && ISDEAD-BLOOD_VAMP_05 && ISDEAD-BLOOD_VAMP_06

	Add gt_BLOOD_DEAD_05

	Engage LAEN BANE 750
	AddControl LAEN MeleeAttack

END

/////////////////////////////////////////////////////////////////////

VIG DeadVampire07 ONESEC && gt_BLOOD_INTRO && gt_BLOOD_DEAD_01 && gt_BLOOD_DEAD_03 && gt_BLOOD_DEAD_05 && !gt_BLOOD_DEAD_07 && ISDEAD-BLOOD_VAMP_07 && ISDEAD-BLOOD_VAMP_08 && ISDEAD-BLOOD_VAMP_09 && ISDEAD-BLOOD_VAMP_10

	EngagePoint BLAND_BKIN_D2 p3_LAEN 750

	Add gt_BLOOD_DEAD_07

	Widescreen TRUE

	// *** CONFRONT LIGHTSTEALER ***
	freecam
	camcut pos06	

	Capture BANE cM_HEWING_STONE Notifies 3 245 BaneStrikesDoor 500 BaneStrikesDoor 800 BaneBreaksDoor

	WHILE !CC-BANE
		Wait 25
	ENDWHILE

	LookAtTurn BANE p3_LAEN

	//"...Hurry!...Let us enter..."
	Say lb0045

	MoveC_1Tel BANE BD_TOWER_IN p5_BANE 
	MoveC_1Tel LAEN		BD_TOWER_IN p5_LAEN 

	//Setup inside of tower now...

	PlaceC	BLOOD_VAMP_13 p5_13
	PlaceC	BLOOD_VAMP_14 p5_14
	PlaceC	BLOOD_VAMP_15 p5_15

	//wait for player to enter tower
	UUComplete BANE
	UUComplete LAEN
	IF !DISTFROM-P-LAEN-10
		MoveC_1Tel P		BD_TOWER_IN p5_P run
	ELSE
		MoveC_1Tel P		BD_TOWER_IN p5_P 
	ENDIF

	Playmusic STOP!

camcut P
	UUComplete P

	camcut ls06
	setcammoveconstant 7
	campan ls05
	freecam

	LookAtTurn BANE P


	//"Young Moon...we are ready to free our lands from the undead."
	Say lb0046

	LookAtTurn BANE LAEN
	LookAtTurn LAEN BANE
	//"Laen...wait outside...would not be wise to endanger...the House of Tortalaran..."
	Say lb0047

	LookAtTurn P LAEN
	//"As you command, father."
	Say da043e

	MoveC_1Tel LAEN BD_TOWER_OUT p3_LAEN

	// Bane, P move to Lightstealer mosaic

	MoveC BANE p6_BANE
	Wait 500
	MoveC P p6_P

	camcut ls07
	setcammoveconstant 20
	campan ls02
	Playmusic rpg29.wav

	UUComplete BANE
	
	UUCameraComplete

	// *** The coffins move ***

	RDoorLocked cof_1
	PlaySFXPosid IG_118.WAV p6_15
	MoveC BLOOD_VAMP_15 p6_15
	camcut cof_1
	UUDoorStill cof_1
	wait 500

	RDoorLocked cof_3
	PlaySFXPosid IG_118.WAV p6_13
	MoveC BLOOD_VAMP_13 p6_13
	camcut cof_3
	UUDoorStill cof_3
	wait 500

	RDoorLocked cof_2
	PlaySFXPosid IG_118.WAV p6_14
	MoveC BLOOD_VAMP_14 p6_14
	camcut ls02
	UUDoorStill cof_2

	// *** Lightstealer appears ***

	PlaySFXPosid IG_71.WAV p6_LS
	PlaceC LIGHTSTEALER p6_LS
	FX_GreenFire LIGHTSTEALER
	Wait 1500
	FX_Sprinkle LIGHTSTEALER
	Capture LIGHTSTEALER cM_CAST_SPELL20_MISC
	wait 1000

	// *** The door locks ***

	camcut ls05
	Wait 500
	SetDoorSpeed dBLOOD_TOWER 2400
	RDoorClosed dBLOOD_TOWER
	UUDoorStill dBLOOD_TOWER
	IDoorLocked dBLOOD_TOWER
	PlaySFXPosid IG_302.WAV pBAR_DOOR_2
	IDoorLocked dBLOOD_TOWER
	SetDoorSpeed dBLOOD_TOWER 300
	FX_LockDoor pBAR_DOOR_2
	wait 2000

	// *** Cut the camera back to lightstealer ***

	camcut ls02
	Wait 950
	UUComplete LIGHTSTEALER

	// LS and vamps descend the stairs
	MoveC LIGHTSTEALER p7_LS

	// Pan the camera down-stairs from lightslealer
	setcammoveconstant 15
	campan ls04

	MoveC BANE p7_BANE

	MoveC BLOOD_VAMP_13 p7_13
	AddControl BLOOD_VAMP_13 LookAtTurn P
	Wait 250
	MoveC BLOOD_VAMP_14 p7_14
	AddControl BLOOD_VAMP_14 LookAtTurn P
	Wait 150
	MoveC BLOOD_VAMP_15 p7_15
	AddControl BLOOD_VAMP_15 LookAtTurn P

	UUComplete LIGHTSTEALER

	//"So. The line of Tortalaran...offer your blood to me."
	Say gh0001

	Capture BANE cM_GUARD_STAND1
	//"I fight for the honour of the White Moon. You cannot defeat me."
	Say lb0048

	MeleeAttack BANE
	Wait 350
	MeleeAttack LIGHTSTEALER
	Wait 250
	GiveSightOfPlayerTo BLOOD_VAMP_13
	AttackDemo2 BLOOD_VAMP_13
	Wait 150
	GiveSightOfPlayerTo BLOOD_VAMP_14
	AttackDemo2 BLOOD_VAMP_14
	Wait 250
	GiveSightOfPlayerTo BLOOD_VAMP_15
	AttackDemo2 BLOOD_VAMP_15
	Wait 500

	IDoorLocked cof_1
	IDoorLocked cof_2
	IDoorLocked cof_3

	camcut P
	camnlock 0
	Widescreen FALSE

	Add gt_BANE_v_LIGHTSTEALER
	ChangeProfileToNotDestiny bbloodkin_bane

	//Collect remaining bloodkin outside with Chant
	EngagePoint BLAND_BKIN_A1 p3_LAEN 550
	EngagePoint BLAND_BKIN_A2 p3_LAEN 600
	EngagePoint BLAND_BKIN_A3 p3_LAEN 650
	EngagePoint BLAND_BKIN_C3 p3_LAEN 700

	normalcam
	setcammovenormal
END

/////////////////////////////////////////////////////////////////////

VIG BaneFightsLightstealer HALFSEC && gt_BANE_v_LIGHTSTEALER && !ISDEAD-BANE

	IF HPLESSTHAN-LIGHTSTEALER-hp_LIGHTSTEALER
		SetHP BANE 1
	ELSE
		SetHP BANE 2000
	ENDIF

END

/////////////////////////////////////////////////////////////////////

VIG DeathOfBane ONESEC && gt_BANE_v_LIGHTSTEALER && ISDEAD-BANE && !ISDEAD-LIGHTSTEALER

	Remove gt_BANE_v_LIGHTSTEALER

	Widescreen TRUE

	LookAtTurn LIGHTSTEALER P

	IF !ISDEAD-BLOOD_VAMP_13 || !ISDEAD-BLOOD_VAMP_14 || !ISDEAD-BLOOD_VAMP_15
		//"Away, my pretty ones. The blood of the well is mine."
		QuickSay gh0002

		Wait 500
		LookAtTurnFollow BLOOD_VAMP_13 LIGHTSTEALER
		Wait 150
		LookAtTurnFollow BLOOD_VAMP_14 LIGHTSTEALER
		Wait 50
		LookAtTurnFollow BLOOD_VAMP_15 LIGHTSTEALER
		Wait 500
	ENDIF

	LookAtTurnFollow P LIGHTSTEALER

	IF !ISDEAD-BLOOD_VAMP_13
		FX_GreenFire BLOOD_VAMP_13
	ENDIF
	KillC BLOOD_VAMP_13
	Wait 250

	IF !ISDEAD-BLOOD_VAMP_14
		FX_GreenFire BLOOD_VAMP_14
	ENDIF
	KillC BLOOD_VAMP_14
	Wait 150

	IF !ISDEAD-BLOOD_VAMP_15
		FX_GreenFire BLOOD_VAMP_15
	ENDIF
	KillC BLOOD_VAMP_15
	Wait 1500

	UUSay

	//"Welcome to my kingdom, Soulbringer. I can sense your blood..."
	Say gh0006

	GiveSightOfPlayerTo LIGHTSTEALER
	AttackDemo2 LIGHTSTEALER

	Widescreen FALSE

	Add gt_P_v_LIGHTSTEALER

END

/////////////////////////////////////////////////////////////////////

VIG DeathOfLightstealer ONESEC && gt_BLOOD_DEAD_07 && !gt_BLOOD_DONE && ISDEAD-LIGHTSTEALER

	Remove gt_P_v_LIGHTSTEALER

	NormalDamageNA BANE 5

	Add gt_BLOOD_DONE

	IDoorClosed dBLOOD_TOWER
	IDoorOpen dBLOOD

	QLRemove ql025
	QLRemove ql026
	Add mj_DEFEAT_LIGHTSTEALER
	AwardEP xp_DEFEAT_LIGHTSTEALER

END

/////////////////////////////////////////////////////////////////////

VIG EndOFTowerOfBlood FIVESEC && gt_BLOOD_DONE && INAREA-P-NEAR_TOWER

	Widescreen TRUE

	Remove gt_BLOOD_DONE
	Remove gt_BLOOD_INTRO

	freecam
	camcut ls08

	//"The Vampire King is defeated...Let us return to Shadowguard..."
	Say da043f

	MoveC LAEN p1_LAEN
	Wait 50
	MoveC P p1_P
	Wait 50
	MoveC BLAND_BKIN_A1 p1_A1
	Wait 50
	MoveC BLAND_BKIN_A2 p1_A2
	Wait 50
	MoveC BLAND_BKIN_A3 p1_A3
	Wait 50
	MoveC BLAND_BKIN_C3 p1_C2
	Wait 50
	MoveC BLAND_BKIN_D2 p1_D2

	Wait 1000
	RunS PalFadeBLACK

	DeleteObjectsInWorldWithID bloodmaster

	PostMsg t_MN_LEAVE

	camcut P
	normalcam
END

/////////////////////////////////////////////////////////////////////

VIG TowerDoor1Barred ONESEC && gt_BLOOD_INTRO && INAREA-P-NEAR_DOOR1

	FX_LockDoor pBAR_DOOR_1

END

/////////////////////////////////////////////////////////////////////

VIG TowerDoor2Barred ONESEC && (gt_BANE_v_LIGHTSTEALER || gt_P_v_LIGHTSTEALER) && INAREA-P-NEAR_DOOR2

	FX_LockDoor pBAR_DOOR_2

END

/////////////////////////////////////////////////////////////////////
