//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();

	if (gf(98,4) > 1)
		erase_char(ME);
		
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (gf(98,4) < 2) {
		
		if (get_memory_cell(3) == 5) { // mage
			if ((get_nearest_party_char(5) >= 0) && (gf(84,1) == 0))
				sf(84,1,1);
			if ((gf(84,1) > 0) && (tick_difference(last_walk,get_current_tick()) > 0) && (get_ran(1,0,100) < 50)) {
				last_walk = get_current_tick();
				inc_flag(84,1,1);
				if (gf(84,1) == 6) {
					sf(98,4,2);
					begin_talk_mode(7);
					}
				else if (gf(84,1) == 5) {
					shoot_projectile(ME,33,397,73);
					pc_heard_sound_delay(178,100);						
					run_char_animation(2,1,35);	
					begin_talk_mode(6);
					}
				else if (my_id() == 9072) {
					shoot_projectile(ME,34,397,73);
					pc_heard_sound_delay(178,100);						
					run_char_animation(2,1,35);	
					}
				else {
					shoot_projectile(ME,35,397,73);
					pc_heard_sound_delay(178,100);						
					run_char_animation(2,1,35);	
					}

				}
			}
		}
		
	if (gf(98,4) > 1) {
		if (dist_to_nav_point(ME,0) <= 2)
			erase_char(ME);
		approach_nav_point(ME,0,1);
		}		
		else if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
			if (get_ran(1,1,100) < 40) 
				return_to_start(ME,1);
			}
			else if (get_memory_cell(0) == 0) {
				fidget(ME,25);
				}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (gf(98,4) > 1) {
		print_str("Talking: The workers are all storming away from the dig.");
		print_str("  None of them stop to talk to you.");
		}
		else begin_talk_mode(get_memory_cell(3));
break;