// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home. A conversation can be set for it,
// if it's friendly.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short i,target;
short tried_return = 0;

body;

beginstate INIT_STATE;
	set_level(ME,35);
	set_boss_level(ME,1);
	set_attack_bonus(ME,2);
	
	alter_stat(ME,28,10);
	alter_stat(ME,30,10);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if (gf(68,9) == 0) {
		if ((get_nearest_party_char(7) >= 0) || (who_shot_me() >= 0)) {
			sf(68,9,1);
			set_attitude(30020,10);
			set_act_at_dist(30020,1);
			set_attitude(30021,10);
			set_act_at_dist(30021,1);
			begin_talk_mode(10);
			}
		end();
		}
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	// if we're hostile, hunt party down
	if ((get_attitude(ME) >= 10) && (dist_to_party() <= 8)) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}
			else {
				if (my_dist_from_start() >= 6) {
					return_to_start(ME,1);
					}
					else if (get_memory_cell(0) == 0) {
						tried_return = 0;
						fidget(ME,25);
						}

				}
				
	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (char_ok(7364)) {
		set_attack_bonus(ME,2);
		set_resistance(ME,7,30);
		}
		else {
			set_attack_bonus(ME,40);
			set_resistance(ME,7,80);
			}
			
	if (target_ok() == FALSE)
		set_state(START_STATE);
	if (my_dist_from_start() <= 12) {
		alert_char(30020);
		alert_char(30021);
		}
		
	if ((my_dist_from_start() >= 15) && (tried_return < 3)) {
		tried_return = tried_return + 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}

	do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;