//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();

	set_name(ME,"Avernite Slave");
	
	if (gf(55,5) > 0)
		erase_char(ME);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if ((gf(55,7) > 0) || (get_attitude(ME) >= 10)) {
		if (dist_to_nav_point(ME,0) <= 2) {
			award_party_xp(100,25);
			sf(55,5,1);
			print_str_color("A slave escapes into the low tunnels!",3);
			erase_char(ME);
			end();
			}
		approach_nav_point(ME,0,1);
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	begin_talk_mode(8);
break;