// summonnpc.txt
// Like basicnpc, but creature can potentially summon a creature every turn or
// more to help it
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5,6,7 - Character ids of creatures it can summon
//   Cell 8 - number of turns between summons, defaults to 2
//   Cell 9 - If 0, summoned creature is normal. Otherwise, the amount that it
//      is buffed

begincreaturescript;

variables;

short i,target;
short tried_return = 0;
short last_abil;
short char_got;
short char_got2;

body;

beginstate INIT_STATE;
	set_name(ME,"Galgath");
	set_courage(ME,100);
	set_resistance(ME,7,90);
	set_boss_level(ME,2);
	change_max_health(ME,200);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);

	last_abil = get_current_tick();
	
	if (gf(153,5) > 0)
		erase_char(ME);
	break;

beginstate DEAD_STATE;
	sf(153,5,1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			tried_return = 0;
			fidget(ME,25);
			}

	if (get_ran(1,0,100) < 10)
		give_char_text_bubble(16545,"Go away.");
	if (get_ran(1,0,100) < 10)
		give_char_text_bubble(16545,"I'm trying to rest.");
	if (get_ran(1,0,100) < 10)
		give_char_text_bubble(16545,"Zzzzz.");
		
	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (get_health(ME) < 500) {
		erase_char(ME);
		erase_char(15646);
		erase_char(15647);
		erase_char(15648);
		erase_char(15649);
		erase_char(15650);
		erase_char(15651);
		erase_char(15652);
		erase_char(15653);
		reward_give(439);
		sf(153,5,1);
		begin_talk_mode(7);
		}
	
	if (target_ok() == FALSE)
		set_state(START_STATE);

	if ((my_dist_from_start() >= 25) && (tried_return == 0)) {
		tried_return = 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}

	char_got = -1;
	char_got2 = -1;
	
	if (tick_difference(last_abil,get_current_tick()) >= 1) {
		i = get_ran(1,0,7);
		if (char_ok(16546 + i) == FALSE)
			char_got = 16546 + i;
		i = get_ran(1,0,7);
		if (char_ok(16546 + i) == FALSE)
			char_got2 = 16546 + i;
		if (char_got2 == char_got)
			char_got2 = -1;

		if ((char_got > 0) || (char_got2 > 0)) {
			print_named_str(ME,"calls some of the infernal legions.");
			
			if (char_got >= 0) {	
				summon_creature(char_got);
				place_particle_num(char_got,1,1,8);
				set_summon_level(char_got,1);
				set_level(char_got,15);
				set_boss_level(char_got,-1);
				set_attack_bonus(char_got,10);
				set_name(char_got,"Infernal Expendable");
				
				if (get_ran(1,0,3) == 1) {
					set_name(char_got,"Infernal Ice Imp");
					set_coloradj(char_got,1024);
					set_new_abil(char_got,14);
					}
				}
			if (char_got2 >= 0) {	
				summon_creature(char_got2);
				place_particle_num(char_got2,1,1,8);
				set_summon_level(char_got2,1);
				set_level(char_got2,15);
				set_boss_level(char_got2,-1);
				set_attack_bonus(char_got2,10);

				set_name(char_got2,"Infernal Expendable");
				if (get_ran(1,0,3) == 1) {
					set_name(char_got2,"Infernal Curse Imp");
					set_coloradj(char_got2,512);
					set_new_abil(char_got2,15);
					}
				}
				
			pc_heard_sound_delay(136,100);						
			last_abil = get_current_tick();
			run_char_animation(2,1,35);	
			end();
			}
		
		}
	
	do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
			
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;