//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;
short last_abil;
short r1;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();
	last_abil = get_current_tick();


	set_name(ME,"X");
	set_boss_level(ME,1);
	
	set_walk_speed(ME,0);
	set_courage(ME,100);
	set_resistance(ME,7,90);
	
	erase_char(18072);
	erase_char(18073);
	erase_char(18074);
	break;

beginstate DEAD_STATE;
	if (gf(167,18) == 0) {
		begin_talk_mode(27);
		}
break;

beginstate START_STATE; 
	if (char_ok(18072))
		erase_char(18072);
	if (char_ok(18073))
		erase_char(18073);
	if (char_ok(18074))
		erase_char(18074);
	
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (gf(167,18) > 0) {
		approach_nav_point(ME,4,1);
		if (dist_to_nav_point(ME,4) <= 2) {
			begin_talk_mode(25);
			}
		}

	// refill a pool
	if ((gf(167,19) > 0) && (tick_difference(last_abil,get_current_tick()) > 4)) {
		r1 = get_ran(1,0,2);
		if (gf(167,23 + r1) == 0) {
			last_abil = get_current_tick();
			sf(167,23 + r1,1);
			if (dist_to_party() <= 7)
				print_str_color("The magic of X slowly fills another of the basins.",3);
			}
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);


	// refill a pool
	if ((gf(167,19) > 0) && (tick_difference(last_abil,get_current_tick()) > 4)) {
		r1 = get_ran(1,0,2);
		if (gf(167,23 + r1) == 0) {
			last_abil = get_current_tick();
			sf(167,23 + r1,1);
			if (dist_to_party() <= 7)
				print_str_color("The magic of X slowly fills another of the basins.",3);
			}
		}

	do_attack();
break;

beginstate TALKING_STATE;
	if ((gf(167,19) > 0) || (gf(167,18) > 0)) {
		print_str("Talking: X is even more distracted than usual.");
		}
		else begin_talk_mode(190);
break;