//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;
short bug_targ = -1;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();

	set_name(ME,"Portal Guard");

	if (gf(165,0) == 0)
		erase_char(ME);

	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if ((bug_targ < 0) || (char_ok(bug_targ) == FALSE) || (dist_to_char(bug_targ) >= 15)) {
		bug_targ = -1;
		}
		
	// one to squish?
	bug_targ = near_char_of_type(200,1);	
	if (bug_targ >= 0) {
		player_see_text("A guard impales one of the imps.");
		give_char_text_bubble(ME,"Got you!");
		pc_heard_sound(158);
		erase_char(bug_targ);
		bug_targ = -1;
		end_combat_turn();
		end();
		}
	
	// any nearby?
	if (bug_targ < 0)
		bug_targ = near_char_of_type(200,6);
	if (bug_targ >= 0) {
		approach_char(ME,bug_targ,1);
		if (get_ran(1,0,100) < 20)
			give_char_text_bubble(ME,"There's one!");
		}	
	if (bug_targ < 0) {
		if (path_a_or_b == 0) {
			if ((tick_difference(last_walk,get_current_tick()) > 4) || (get_memory_cell(4) > 0)) {
				if (approach_nav_point(ME,get_memory_cell(3),2)) {
					last_walk = get_current_tick();
					path_a_or_b = 1;	
					}
				}	
			}
			else {
				if (tick_difference(last_walk,get_current_tick()) > 4) {
					if (return_to_start(ME,2)) {
						last_walk = get_current_tick();
						path_a_or_b = 0;		
						}
					}
				}
		}
		
	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(0) == 0) {
		print_str("Talking: You make a bit of small talk, but don't learn");
		print_str("  anything interesting.");
		}
		else begin_talk_mode(get_memory_cell(0));
break;