// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short last_abil2;
short used_abil = 0;
short ae_range = 8;
short phase = 0;
short mess = 0;

body;

beginstate INIT_STATE;
	set_boss_level(ME,2);
	change_max_health(ME,1800);
	set_courage(ME,100);
	set_resistance(ME,7,100);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	last_abil2 = get_current_tick();
	break;

beginstate DEAD_STATE;
	sf(170,15,1);
	force_char_status(30000,26,0);
	begin_talk_mode(15);
break;

beginstate START_STATE; 
	if (get_attitude(ME) >= 10) {
		// if I have a target for some reason, go attack it
		if (target_ok()) {
			if (dist_to_char(get_target()) <= 16)
				set_state(3);
				else set_foe_target(ME,-1);
			}
		
		// Look for a target, attack it if visible
		if (get_foe_target(ME,12,0)) {
			if (dist_to_party() > 8)
				approach_char(ME,30000,7);
				else {
					do_attack();
					set_state(3);
					}
			}
			
		// Have I been hit? Strike back!
		if (who_shot_me() >= 0) {
			set_foe_target(ME,who_shot_me());
			do_attack();
			set_state(3);
			}
		}
		
	if (phase == 0) {
		if (dist_to_nav_point(ME,0) <= 1) {
			phase = 1;
			sf(13,9,2);
			kill_object(2346,1);
			kill_object(2347,1);
			kill_object(2348,1);
			kill_object(2349,1);
			set_terrain(0,840,34,204 + get_ran(1,0,1));
			set_terrain(0,842,34,204 + get_ran(1,0,1));
			set_terrain(0,843,34,204 + get_ran(1,0,1));
			set_terrain(0,841,37,204 + get_ran(1,0,1));
			set_terrain(0,842,37,204 + get_ran(1,0,1));
			set_terrain(0,844,37,204 + get_ran(1,0,1));
			set_terrain(0,839,35,204 + get_ran(1,0,1));
			set_terrain(0,839,36,204 + get_ran(1,0,1));
			set_terrain(0,845,35,204 + get_ran(1,0,1));
			set_terrain(0,845,36,204 + get_ran(1,0,1));
		
			erase_char(30007);
		
			begin_talk_mode(13);
			}
			else approach_nav_point(ME,0,1);
			
		}
		else {
			if (my_dist_from_start() > 1)
				return_to_start(ME,1);
				else {
					if (get_nearest_party_char(9) >= 0)
						begin_talk_mode(16);
						else erase_char(ME);
					end();
					}
			}

	// if we're hostile, hunt party down
	if (get_attitude(ME) >= 10) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((get_attitude(ME) >= 10) && (mess == 0)) {
		mess = 1;
	last_abil2 = get_current_tick();
		begin_talk_mode(14);
		}
	
	if (target_ok() == FALSE)
		set_state(START_STATE);
	used_abil = 0;

	if ((is_combat()) && (get_nearest_hate_char(ae_range) >= 0) && (tick_difference(last_abil,get_current_tick()) > 0)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

			print_named_str(ME,"breathes a terrifying gout of fire.");
		  	place_particle_num(ME,2,4,8);
			damage_nearby(get_ran(1,3000,3500),ae_range,2,0);
			pc_heard_sound_delay(178,100);						
	  		create_missile_spiral(154,40,ae_range,2);
			status_nearby(-12,ae_range,1,4);
			status_nearby(3,ae_range,27,4);
			status_nearby(-2,ae_range,28,4);
			status_nearby(-2,ae_range,18,4);
		end();
		
		}

	if ((can_see_char(get_target())) && (is_combat()) && (tick_difference(last_abil2,get_current_tick()) > 3)) {
		run_char_animation(2,1,35);	

			print_str_color("Melanchion points at you and mutters a word of power. You",3);
			print_str_color("  feel terribly cold.",3);
			set_char_status(get_target(),26,3);
			//place_particle_num(get_target(),2,2,8);
			pc_heard_sound_delay(174,100);						
			shoot_projectile(ME,char_loc_x(get_target()),char_loc_y(get_target()),34);
	
		last_abil2 = get_current_tick();
		end();
		}


	if (used_abil == 0)
		do_attack();
break;

beginstate TALKING_STATE;

	begin_talk_mode(17);
break;