// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short used_abil = 0;
short ae_range = 6;
short duel_status = 0;
short abil1 = 0;
short abil2 = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Chief Gunza");
	set_courage(ME,100);
	set_resistance(ME,7,90);
	set_boss_level(ME,2);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	if (get_memory_cell(5) != 0)
		ae_range = get_memory_cell(5);
	break;

beginstate DEAD_STATE;
	sf(98,21,1);
	sf(98,18,1);
	begin_talk_mode(17);
	
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	// if we're hostile, hunt party down
	if (get_attitude(ME) >= 10) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}
		
	if ((duel_status == 0) && (gf(98,4) == 5)) {
		if (dist_to_nav_point(ME,0) <= 2)
			duel_status = 1;
			else approach_nav_point(ME,0,1);
		}
		else if ((duel_status == 1) && (gf(98,4) == 5) && (get_nearest_party_char(6) >= 0) && (get_attitude(ME) < 10)) {
			set_attitude(ME,10);
			begin_talk_mode(14);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (get_attitude(ME) >= 10) {
		if (duel_status == 0)
			sf(98,19,1);
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	used_abil = 0;

	if ((get_ran(1,0,100) < 80) && (is_combat()) && (get_nearest_party_char(4) >= 0) && (tick_difference(last_abil,get_current_tick()) > 1)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

			print_named_str(ME,"spins around, cleaving the air with a mighty blow.");
			damage_nearby(get_ran(get_level(ME) + get_attack_bonus(ME),1,8),3,0,0);
			pc_heard_sound_delay(3,100);				
			spray_missiles(15,8,3);
			spray_missiles(20,8,3);
			used_abil = 1;

		
		}
	if ((abil1 == 0) && (get_health(ME) < (get_max_health(ME) * 2) / 3) && (gf(98,19) == 0)) {
		abil1 = 1;
		begin_talk_mode(15);
		}
	if ((abil2 == 0) && (get_health(ME) < (get_max_health(ME) * 1) / 3)) {
		abil2 = 1;
		force_char_status(ME,20,10);
		force_char_status(ME,21,10);
		force_char_status(ME,24,10);
		heal_char(ME,250);
		
		begin_talk_mode(16);
		}
		
	if (used_abil == 0)
		do_attack();
break;

beginstate TALKING_STATE;
	if (gf(98,4) == 5) {
		print_str("Talking: He doesn't respond. The duel is on.");
		end();
		}
	begin_talk_mode(130);
break;