// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short used_abil = 0;
short ae_range = 8;
short fleeing = 0;
short attacks = 0;
short att_phase = 0;
short talked = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Kazass-Hrros");
	set_level(ME,30);
	change_max_health(ME,150);
	set_boss_level(ME,2);
	set_strategy(ME,2);
	
	set_courage(ME,100);
	set_resistance(ME,7,90);

	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	break;

beginstate DEAD_STATE;
	begin_talk_mode(15);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,10,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	// healing
	if ((get_health(ME) < get_max_health(ME)) && (get_nearest_party_char(10) < 0))
		heal_char(ME,200);
		
	// do we hunt?
	if (gf(122,9) > 0) {
		if ((gf(122,10) > 0) && (att_phase == 0)) {
			att_phase = 1;
			set_foe_target(ME,random_group_member(0));
			attacks = 0;
			set_state(3);
			}
		if ((gf(122,11) > 0) && (att_phase == 1)) {
			att_phase = 2;
			set_foe_target(ME,random_group_member(0));
			attacks = 0;
			set_state(3);
			}
		if (gf(122,12) > 0) {
			att_phase = 3;
			set_foe_target(ME,random_group_member(0));
			set_state(3);
			}
		}



	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((get_nearest_party_char(6) >= 0) && (talked == 0)) {
		talked = 1;
		talk_no_exit(30);
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	
	if ((att_phase < 2) && (get_health(ME) < get_max_health(ME) - 500) && (attacks == 0) && (gf(122,12) == 0))  {
		attacks = 0;
		fleeing = 1;
		force_char_status(ME,24,5);
		set_state(4);
		}
		
	used_abil = 0;

	if ((is_combat()) && (get_nearest_party_char(8) >= 0) && (tick_difference(last_abil,get_current_tick()) > 1)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

		if (att_phase == 0) { // ae fire
			print_named_str(ME,"summons a rain of fire.");
		  	place_particle_num(ME,2,4,8);
			damage_nearby(get_ran(get_level(ME) + get_attack_bonus(ME),1,4),ae_range,2,0);
			pc_heard_sound_delay(178,100);						
	  		create_missile_spiral(154,40,ae_range,2);
			used_abil = 1;
			}

		if (att_phase == 1) { // ae terror
		  	place_particle_num(ME,4,10,8);
			print_named_str(ME,"radiates pure terror.");
			status_nearby(get_level(ME) + 5,ae_range,7,4);
			//particle_nearby(ae_range,23,2,4,2);
			pc_heard_sound_delay(177,100);						
			used_abil = 1;
			}

	  	if (att_phase >= 2) { // lightning aura
		  	place_particle_num(ME,1,4,8);
			print_named_str(ME,"surrounds itself with an aura of lightning.");
			pc_heard_sound_delay(179,250);						
	  		create_missile_spiral(147,40,ae_range,2);
	  		damage_nearby(get_ran(1,200,300),ae_range,1,0);
			status_nearby(get_level(ME) / 4,ae_range,22,0);
			used_abil = 1;
	  		}

		
		}

	if (used_abil == 0) {
		do_attack();
		}
break;

beginstate 4; // returning to start
	if ((my_dist_from_start() < 3) || (gf(122,12) > 0)) {
		fleeing = 0;
		set_state(START_STATE);
		}
		
	
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		attacks = attacks + 1;
		if (attacks > 2) {
			att_phase = 2;
			heal_char(ME,1000);
			fleeing = 0;
			set_foe_target(ME,who_shot_me());
			do_attack();
			set_state(3);
			}
		}
	
	return_to_start(ME,1);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;