//leavezone.txt - Basically functions like the default npc, except that, when a stuff done
// flag is set to nonzero, if flees to a navpoint and then disappears.
// Memory Cells:
//   Cell 0 - If 0, default behavior. If 1, it doesnŐt fidget.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is set to 1, flee zone.
//	 Cell 3 - The nav point it flees to.
//   Cell 4 - Number of state when talked to. Plays default text if 0.

begincreaturescript;

variables;

short i,target;
short fleeing = 0;

body;

beginstate INIT_STATE;
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		if (get_flag(get_memory_cell(1),get_memory_cell(2)) > 0)
			erase_char(ME);
	break;

beginstate DEAD_STATE;
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		if (get_flag(get_memory_cell(1),get_memory_cell(2)) > 0)
			set_state(5);
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (get_health(ME) < get_max_health(ME) / 2) {
		set_state(5);
		}

	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate 5; // leaving zone
	fleeing = 1;
	if (approach_nav_point(ME,get_memory_cell(3),1)) {
		if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
			set_flag(get_memory_cell(1),get_memory_cell(2),1);
		erase_char(ME);
		}
break;

beginstate TALKING_STATE;
	if (fleeing) {
		print_named_str(ME,"doesn't want to talk right now.");
		} 
		else if (get_memory_cell(4) == 0) {
			print_str("Talking: You make a bit of small talk, but you don't learn");
			print_str("  anything interesting.");
			}
			else begin_talk_mode(get_memory_cell(4));
break;