//patrolnpc.txt - Like basic monst, but this character spends all its time 
// patrolling among 3 nav points

// this script automatically sets itself to act at a distance

// Memory Cells:
//   Cell 0 - Dialogue node
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The first nav point in the patrol. Creature marches to this point, 
//     then this point + 1, then this point + 2.

begincreaturescript;

variables;

short i,target;
short path_status = 0;

body;

beginstate INIT_STATE;
	set_act_at_dist(ME,1);
	
	if (dist_to_nav_point(ME,get_memory_cell(3) + 1) < dist_to_nav_point(ME,get_memory_cell(3))) {
		path_status = 1;
		if (dist_to_nav_point(ME,get_memory_cell(3) + 2) < dist_to_nav_point(ME,get_memory_cell(3) + 1)) 
			path_status = 2;
		}
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (path_status == 0) {
		if (get_ran(1,0,100) < 90) {
			if (approach_nav_point(ME,get_memory_cell(3),2))
				path_status = 1;	
			}	
		}
		else if (path_status == 1) {
			if (get_ran(1,0,100) < 90) {
				if (approach_nav_point(ME,get_memory_cell(3) + 1,2))
					path_status = 2;	
				}
			}
		else if (path_status == 2) {
			if (get_ran(1,0,100) < 90) {
				if (approach_nav_point(ME,get_memory_cell(3) + 2,2))
					path_status = 0;	
				}
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(0) == 0) {
		print_str("Talking: You make a bit of small talk, but don't learn");
		print_str("  anything interesting.");
		}
		else begin_talk_mode(get_memory_cell(0));
break;