// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short last_abil2;
short used_abil = 0;
short ae_range = 4;
short weak_targ;

body;

beginstate INIT_STATE;
	set_name(ME,"Ghavassa-Oss");
	set_level(ME,32);
	set_boss_level(ME,2);
	set_courage(ME,100);
	set_resistance(ME,7,90);
	change_max_health(ME,200);
	set_attack_bonus(ME,15);
	
	alter_stat(30039,28,10);
	alter_stat(30039,29,10);
	set_new_abil(30039,16);

	last_abil = get_current_tick();
	last_abil2 = get_current_tick();

	break;

beginstate DEAD_STATE;
	sf(170,7,1);
	sf(40,18,1);
	sf(40,19,1);
	sf(40,17,0);
	sf(40,13,1);
	award_party_xp(300,30);
	
	set_attitude(30039,10);
	begin_talk_mode(21);
	
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		

	// if we're hostile, hunt party down
	if (get_attitude(ME) >= 10) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	used_abil = 0;

	if ((get_ran(1,0,100) < 50) && (is_combat()) && (get_nearest_hate_char(ae_range) >= 0) && (tick_difference(last_abil,get_current_tick()) > 1)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

			print_named_str(ME,"spins around, cleaving the air with a mighty blow.");
			damage_nearby(get_ran(get_level(ME) + get_attack_bonus(ME),1,6),ae_range,0,0);
			pc_heard_sound_delay(3,100);				
			spray_missiles(15,8,ae_range);
			spray_missiles(20,8,ae_range);

			status_nearby(-10,ae_range,0,4);
			status_nearby(-10,ae_range,1,4);
			status_nearby(-3,ae_range,20,4);
			status_nearby(-3,ae_range,21,4);
			status_nearby(-3,ae_range,24,4);

			used_abil = 1;
		end();
		}
	if ((is_combat()) && (dist_to_char(get_target()) <= 3) && (tick_difference(last_abil2,get_current_tick()) > 1)) {
		
		run_char_animation(2,1,35);	
		last_abil2 = get_current_tick();

		print_named_str(ME,"flings a foe across the room!");
		damage_char(get_target(),90,0);
		set_char_status(get_target(),17,50);
		
		play_sound(139);

		if (dist_to_loc(get_target(),817,136) > 5)
			relocate_char(get_target(),817,136,0);
			else relocate_char(get_target(),825,143,0);

		get_foe_target(ME,12,0);
		if (target_ok() == FALSE)
			set_state(START_STATE);
		end();
		}
		
	weak_targ = most_frail_pc();

	if ((can_see_char(get_pc_id(weak_targ))) && (dist_to_char(get_pc_id(weak_targ)) <= 5))
		set_foe_target(ME,get_pc_id(weak_targ));

	if (used_abil == 0)
		do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;