// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short used_abil = 0;
short ae_range = 6;
short mess1 = 0;
short mess2 = 0;
short tried_return = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Chitrach Queen");
	set_level(ME,30);
	set_boss_level(ME,2);
	set_new_abil(ME,11);
	set_attack_bonus(ME,8);
	alter_stat(ME,19,7);
	set_aggression(ME,25);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	if (get_memory_cell(5) != 0)
		ae_range = get_memory_cell(5);
	break;

beginstate DEAD_STATE;
	sf(91,6,1);
	begin_talk_mode(9);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}


	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);


	if ((my_dist_from_start() >= 25) && (tried_return == 0)) {
		tried_return = 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}
	
	if (mess1 == 0) {
		mess1 = 1;
		alert_char(30008);
		alert_char(30009);
		alert_char(30010);
		alert_char(30011);
		alert_char(30012);
		begin_talk_mode(7);
		}

	// pit bugs
	i = 9892;
	while (i <= 9898) {
		if (char_ok(i) == FALSE) {
			spawn_creature(i);
			set_name(i,"Pit Chitrach");
			set_summon_level(i,1);
			}
			
		i = i + 1;
		}
	
	// eggs
	if ((gf(91,10) == 0) && (get_health(ME) < (get_max_health(ME) * 5) / 6))
		sf(91,10,1);
	if ((gf(91,11) == 0) && (get_health(ME) < (get_max_health(ME) * 4) / 6))
		sf(91,11,1);
	if ((gf(91,12) == 0) && (get_health(ME) < (get_max_health(ME) * 3) / 6))
		sf(91,12,1);
	if ((gf(91,13) == 0) && (get_health(ME) < (get_max_health(ME) * 2) / 6))
		sf(91,13,1);
		
	used_abil = 0;

	if ((get_health(ME) < (get_max_health(ME) * 3) / 6) && (get_ran(1,0,100) < 80) && (is_combat()) && (get_nearest_hate_char(6) >= 0) && (tick_difference(last_abil,get_current_tick()) > 1)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

			print_named_str(ME,"lets out a long, deafening screech!");
			damage_nearby(get_ran(get_level(ME),1,6),ae_range,0,0);
			status_nearby(get_level(ME) + 10,ae_range,17,4);
			status_nearby(3,ae_range,27,4);
			status_nearby(-10,ae_range,0,4);
			status_nearby(-31,ae_range,1,4);
			particle_nearby(ae_range,5,2,4,8);
			pc_heard_sound_delay(187,100);			
			used_abil = 1;

		if (mess2 == 0) {
			mess2 = 1;
			begin_talk_mode(8);
			}
		end();
		}

	if (used_abil == 0)
		do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;