// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6
//  cell 6 - 0 - mode 1, 1 - mode 2

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short used_abil = 0;
short ae_range = 8;
short did_talk = 0;
short tried_return = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Cackling Demon");
	set_level(ME,15);
	set_boss_level(ME,2);
	set_aggression(ME,55);
	change_max_health(ME,200);
	set_new_abil(ME,20);
	
	if ((get_memory_cell(6) == 0) && (gf(164,3) > 0))
		erase_char(ME);
		
	last_abil = get_current_tick();

	break;

beginstate DEAD_STATE;
	print_str_color("The wastes have been purged of this cackling terror.",3);
	sf(164,3,4);
break;

beginstate START_STATE; 
	if ((get_memory_cell(6) == 0) && (did_talk == 0) && (get_nearest_party_char(6) >= 0)) {
		did_talk = 1;
		begin_talk_mode(50);
		}
	if ((get_memory_cell(6) == 1) && (did_talk == 0) && (get_nearest_party_char(6) >= 0)) {
		did_talk = 1;
		begin_talk_mode(51);
		}
	
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	used_abil = 0;

	if ((get_memory_cell(6) == 0) && (did_talk == 0)) {
		did_talk = 1;
		begin_talk_mode(50);
		}
	if ((get_memory_cell(6) == 1) && (did_talk == 0)) {
		did_talk = 1;
		begin_talk_mode(51);
		}


	if ((is_combat()) && (tick_difference(last_abil,get_current_tick()) > 1)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

		if (get_memory_cell(6) == 1) { // ae terror
			print_named_str(ME,"summons a rain of infernal fire.");
		  	place_particle_num(ME,2,4,8);
			damage_nearby(get_ran(get_level(ME) + get_attack_bonus(ME),1,6),ae_range,2,0);
			pc_heard_sound_delay(178,100);						
			status_nearby(-12,ae_range,0,4);
	  		create_missile_spiral(154,40,ae_range,2);
			used_abil = 1;
			}

		if (get_memory_cell(6) == 0) { // ae terror
		  	place_particle_num(ME,4,10,8);
			print_named_str(ME,"lets out a long, cackling howl.");
			status_nearby(get_level(ME) + 5,ae_range,7,4);
			//particle_nearby(ae_range,23,2,4,2);
			pc_heard_sound_delay(177,100);						
			used_abil = 1;
			}

		
		}

	if (get_health(ME) < get_max_health(ME) / 2) {
		if (get_memory_cell(6) == 0) {
			sf(164,3,1);
			erase_char(ME);
			begin_talk_mode(52);
			}
		if (get_memory_cell(6) == 1) {
			sf(164,3,2);
			erase_char(ME);
			begin_talk_mode(53);
			}

		}
		
	if ((my_dist_from_start() >= 25) && (tried_return == 0)) {
		tried_return = 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}
		
	if (used_abil == 0)
		do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	return_to_start(ME,2);
break;
beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;