// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short last_abil2;
short used_abil = 0;
short ae_range = 6;
short which_ae = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Lord of the Fungus");
	set_courage(ME,100);
	set_resistance(ME,7,90);
	set_boss_level(ME,2);
	set_attack_bonus(ME,20);
	set_new_abil(ME,20);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	if (get_memory_cell(5) != 0)
		ae_range = get_memory_cell(5);
	break;

beginstate DEAD_STATE;
	sf(50,6,1);
	
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	used_abil = 0;

	if ((is_combat()) && (get_nearest_hate_char(ae_range) >= 0) && (tick_difference(last_abil,get_current_tick()) > 0) )  {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();
	  		create_missile_spiral(149,40,ae_range,2);
		if (which_ae < 4)
			print_named_str(ME,"sprays a cloud of disorienting spores.");
		if (which_ae == 0) { // ae slow
		  	place_particle_num(ME,3,9,8);
			status_nearby(-12,ae_range,1,4);
			status_nearby(-12,ae_range,0,4);
			status_nearby(8,ae_range,27,4);
			//particle_nearby(ae_range,2,2,4,8);
			pc_heard_sound_delay(174,100);						
			which_ae = 1;
			used_abil = 1;
			}
		else if (which_ae == 1) { // ae terror
		  	place_particle_num(ME,4,10,8);
			status_nearby(get_level(ME) + 5,ae_range,7,4);
			//particle_nearby(ae_range,23,2,4,2);
			pc_heard_sound_delay(177,100);						
			which_ae = 2;
			used_abil = 1;
			}
		else if (which_ae == 2) { // ae daze
		  	place_particle_num(ME,3,1,8);
			status_nearby(get_level(ME) + 12,ae_range,17,4);
			//particle_nearby(ae_range,8,2,4,2);
			pc_heard_sound_delay(195,100);			
			which_ae = 3;
			used_abil = 1;
			}
		else if (which_ae == 3) { // ae charm
		  	place_particle_num(ME,16,10,10);
			status_nearby(get_level(ME) + 5,ae_range,5,4);
			//particle_nearby(ae_range,17,2,4,8);
			pc_heard_sound_delay(100,100);						
			which_ae = 4;
			used_abil = 1;
			print_str_color("Pores are opening on the beast's sides. Something awful is about to spray out.",3);
			}
		else if (which_ae == 4) {   // ae acid + damage
			print_named_str(ME,"sprays a cloud of noxious, poisonous goo.");
		  	place_particle_num(ME,4,6,8);

	  		damage_nearby(get_ran(1,300,400),ae_range,5,0);
			pc_heard_sound_delay(177,100);						
			used_abil = 1;
			which_ae = 0;
			}

		
		}

	if ((tick_difference(last_abil2,get_current_tick()) >= 3) && (my_dist_from_start() <= 12)) {
		last_abil2 = get_current_tick();
		if ((get_health(ME) < get_max_health(ME) / 2) && ((char_ok(5437)) || (char_ok(5438))) ) {
			print_str_color("The weakening fungal creature seizes and devours a ball of slime.",3);
			run_char_animation(2,1,35);	
			heal_char(ME,2500);
			run_char_animation(2,1,35);	
			play_sound(138);
			if (char_ok(5437)) 
				damage_char(5437,5000,1);
				else damage_char(5438,5000,1);
			}
			else if ((char_ok(5437) == FALSE) || (char_ok(5438) == FALSE)) {
				play_sound(256);
				if (char_ok(5437)) 
					i = 5438;
					else i = 5437;
				if (spawn_creature(i)) {
					print_str_color("A hideous glob of slime crawls out of one of the pools.",2);
					place_particle_num(i,1,1,8);
					set_summon_level(i,1);
					set_boss_level(i,-1);
					run_char_animation(2,1,35);	
					}
				}
		}
		
	if (used_abil == 0)
		do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;