//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;
short last_tick;
short kill_counter = 0;
short talking = 0;
short last_abil;
short used_disc;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();
	last_tick = get_current_tick();

	last_abil = get_current_tick();

	set_name(ME,"Arilda");
	set_level(ME,12);
	set_boss_level(ME,1);
	change_max_health(ME,40);
	set_courage(ME,100);
	set_resistance(ME,7,90);
	set_new_abil(ME,20);

	if (gf(148,1) > 0)
		erase_char(ME);
	break;

beginstate DEAD_STATE;
	begin_talk_mode(13);
break;

beginstate START_STATE; 
	if ((gf(148,17) == 2) || (gf(148,16) > 0)) {
		if (tick_difference(last_tick,get_current_tick()) > 0) {
			last_tick = get_current_tick();
			kill_counter = kill_counter + 1;
			}
		}
	if ((kill_counter >= 5) && (gf(148,16) > 0) && (gf(148,1) == 0) && (gf(148,11) == 0) && (gf(148,13) < 3))
		set_state(4);
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (gf(148,14) > 0) {
			if (path_a_or_b == 0) {
				if (dist_to_nav_point(ME,2) <= 2)
					path_a_or_b = 1;
					else approach_nav_point(ME,2,1);
				}
				else {
					approach_nav_point(ME,3,4);
					}
		}
		


	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if ((gf(148,17) == 2) || (gf(148,16) > 0)) {
		if (tick_difference(last_tick,get_current_tick()) > 0) {
			last_tick = get_current_tick();
			kill_counter = kill_counter + 1;
			}
		}
	if ((kill_counter >= 5) && (gf(148,1) == 0) && (gf(148,11) == 0) && (gf(148,13) < 3))
		set_state(4);
	
	if ((talking == 0) && (get_nearest_party_char(8) >= 0)) {
		talking = 1;
		begin_talk_mode(12);
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);

	// use a disc?
	if ((is_combat()) && (get_char_status(ME,27) == 0) && (get_ran(1,0,100) < 75)) {
		used_disc = 0;

		if ((used_disc == 0) && ((get_char_status(ME,0) < 0) || (get_char_status(ME,8) < 0)) && (get_ran(1,0,100) < 60) ) {
			use_discipline(ME,3);
			used_disc = 1;
			}

		if ((used_disc == 0) && (get_ran(1,0,100) < 60)) {
			use_discipline(ME,2);
			used_disc = 1;
			}
		if ((used_disc == 0) && (get_ran(1,0,100) < 60)) {
			use_discipline(ME,1);
			used_disc = 1;
			}
		if (used_disc == 0)
			use_discipline(ME,0);
		
		}


	do_attack();
break;

beginstate 4; // returning to start
	if ((gf(148,1) > 0) || (gf(148,11) > 0))
		set_state(START_STATE);
	if (who_shot_me() >= 0) 
		kill_counter = kill_counter + 1;
	if (kill_counter >= 10) {
		kill_counter = 0;
		set_state(START_STATE);
		}
		
	if (approach_nav_point(ME,4,1)) {
		sf(148,13,3);
		erase_char(16017);
		erase_char(16018);
		erase_char(16019);
		print_str_color("You hear horrifying screaming in the distance.",3);
		set_state(START_STATE);
		}
break;

beginstate TALKING_STATE;
	if (get_memory_cell(0) == 0) {
		print_str("Talking: You make a bit of small talk, but don't learn");
		print_str("  anything interesting.");
		}
		else begin_talk_mode(get_memory_cell(0));
break;