//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - If nonzero, the character runs to its nav point immediately.
//     If 0, only goes occasionally.
// 5,6 - hounds to spawn

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;

body;

beginstate INIT_STATE;
	set_name(ME,"Woods Hellhound");
	set_level(ME,22);
	set_aggression(ME,50);
	
	if (gf(95,1) > 0)
		erase_char(ME);
		
	last_walk = get_current_tick();

	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if ((path_a_or_b == 0) && (get_nearest_party_char(7) >= 0)) {
		print_str_color("A hellhound sees you. It tries to flee off",2);
		print_str_color("  into the brush to defend its pack.",2);
		set_state(4);
		}
	
	if (path_a_or_b > 0) {
		// if I have a target for some reason, go attack it
		if (target_ok()) {
			if (dist_to_char(get_target()) <= 16)
				set_state(3);
				else set_foe_target(ME,-1);
			}
		
		// Look for a target, attack it if visible
		if (get_foe_target(ME,12,0)) {
			if (dist_to_party() > 8)
				approach_char(ME,30000,7);
				else {
					do_attack();
					set_state(3);
					}
			}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (my_dist_from_start() >= 6) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (path_a_or_b == 0) {
		print_str_color("A hellhound sees you. It tries to flee off",2);
		print_str_color("  into the brush to defend its pack.",2);
		set_state(4);
		}
		
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate 4; // returning to start
	path_a_or_b = 1;
	set_act_at_dist(ME,1);
	
	if ((who_shot_me() >= 0) && (get_health(ME) < get_max_health(ME) / 2)) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	if (dist_to_nav_point(ME,1) <= 1) {
		player_see_text("The hellhound disappears into a hole in the ground.");
		spawn_creature(get_memory_cell(5));
		spawn_creature(get_memory_cell(6));
		erase_char(ME);
		end();
		}
		
	approach_nav_point(ME,1,2);
break;


beginstate TALKING_STATE;
	if (get_memory_cell(0) == 0) {
		print_str("Talking: You make a bit of small talk, but don't learn");
		print_str("  anything interesting.");
		}
		else begin_talk_mode(get_memory_cell(0));
break;