// aenpc.txt
// A monster with a special ability scripted in. The ability is an AE, used 
// every 2-3 turns or so.

// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - The ability.
//   Cell 5 - The range of the ae, defaults to 6

// The abilities:
// 0 - AE Slow
// 1 - AE Curse
// 2 - AE Fire (1-4 dam per level)
// 3 - AE Acid
// 4 - AE Terror
// 5 - AE Daze
// 6 - AE Debuff
// 7 - AE Cold (1-6 dam per level)
// 8 - AE Energy (1-8 dam per level)
// 9 - AE Charm
// 10 - AE Poison
// 11 - AE mana drain
// 12 - AE mana drain + damage
// 13 - stomps feet
// 14 - lightnign aura
// 15 - cleave (1-8 dam per level)
// 16 - AE Curse & Weaken
// 17 - AE Acid + damage

begincreaturescript;

variables;

short i,target;
short last_abil;
short last_abil2;
short weak_targ;
short used_abil = 0;
short ae_range = 6;
short call_counter = 0;
short alert = 0;

body;

beginstate INIT_STATE;
	set_name(ME,"Chief Rrgala");
	set_boss_level(ME,2);
	set_new_abil(ME,1);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);
	last_abil = get_current_tick();
	last_abil2 = get_current_tick();
	if (get_memory_cell(5) != 0)
		ae_range = get_memory_cell(5);
	break;

beginstate DEAD_STATE;
	inc_flag(48,11,1);
break;

beginstate START_STATE; 
	if (alert == 0) {
		if ((get_nearest_party_char(8) >= 0) || (who_shot_me() >= 0)) {
			alert = 1;
			begin_talk_mode(12);
			}
			
		end();
		}
	if (alert == 1) {
		if ((get_nearest_party_char(4) >= 0) || (who_shot_me() >= 0)) {
			alert = 2;
			last_abil2 = get_current_tick();
			begin_talk_mode(13);
			}
			
		end();
		}
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}


	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	used_abil = 0;

	if ((get_ran(1,0,100) < 80) && (is_combat()) && (get_nearest_hate_char(ae_range) >= 0) && (tick_difference(last_abil,get_current_tick()) > 1)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

			print_named_str(ME,"stomps his feet!");
			damage_nearby(get_ran(get_level(ME),1,8),4,0,0);
			status_nearby(get_level(ME) + 10,4,17,4);
			particle_nearby(4,5,2,4,8);
			pc_heard_sound_delay(187,100);			
		
			if (call_counter < 5) {
				if (char_ok(5238 + call_counter)) {
					set_attitude(5238 + call_counter,10);
					set_act_at_dist(5238 + call_counter,1);
					}
				call_counter = call_counter + 1;
				}	
		end();

		
		}

	if ((get_ran(1,0,100) < 80) && (is_combat()) && (dist_to_char(get_target()) <= 3) && (tick_difference(last_abil2,get_current_tick()) > 2)) {
		
		run_char_animation(2,1,35);	
		last_abil2 = get_current_tick();

		print_named_str(ME,"smashes you mightily with his club!");
		damage_char(get_target(),500,0);
		set_char_status(get_target(),17,50);
		
		play_sound(139);
		
		if (num_chars_in_group(0) > 1) {
			if (dist_to_loc(get_target(),390,236) > 5)
				relocate_char(get_target(),390,236,0);
				else relocate_char(get_target(),388,247,0);
			}
		get_foe_target(ME,12,0);
		if (target_ok() == FALSE)
			set_state(START_STATE);
		end();
		}

	weak_targ = most_frail_pc();


	if ((can_see_char(get_pc_id(weak_targ))) && (dist_to_char(get_pc_id(weak_targ)) <= 5))
		set_foe_target(ME,get_pc_id(weak_targ));

	if (used_abil == 0)
		do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;