//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - The nav point the character marches out to.
//   Cell 4 - which dude 0 - solb 1 - andros 2 - vand

begincreaturescript;

variables;

short i,target;
short path_a_or_b = 0;
short last_walk;

body;

beginstate INIT_STATE;
	last_walk = get_current_tick();

	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	if (get_memory_cell(4) == 0) { // solb
		if (gf(82,4) == 2) {
			if (dist_to_nav_point(ME,0) > 1)
				approach_nav_point(ME,0,1);
				else {
					set_facing(ME,3);
					if ((get_nearest_party_char(5) >= 0) && (dist_to_char(8856) <= 7))
						talk_no_exit(210);
					}
			}
		if (gf(82,4) == 3) {
			if (dist_to_nav_point(ME,3) > 1)
				approach_nav_point(ME,3,1);
				else {
						begin_talk_mode(16);
					}
			
			}
		}
	if (get_memory_cell(4) == 1) { // andros
		if (gf(82,4) == 2) {
			if (dist_to_nav_point(ME,2) > 1)
				approach_nav_point(ME,2,1);
				else {
					set_facing(ME,7);
					}
			}
			else {
					return_to_start(ME,1);
				}
		}
	if (get_memory_cell(4) == 2) { // vanderin
		if (gf(82,4) == 2) {
			if (dist_to_nav_point(ME,1) > 1)
				approach_nav_point(ME,1,1);
				else {
					set_facing(ME,1);
					}
			}
		if (gf(82,4) == 3) {
			if (dist_to_nav_point(ME,3) > 1)
				approach_nav_point(ME,3,1);

			
			}
		if (gf(82,4) < 2) {
				if (my_dist_from_start() >= 6) {
					return_to_start(ME,1);
					}
					else fidget(ME,25);
				}
		}
		

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if ((get_memory_cell(4) == 1) && (gf(82,4) > 2) && (gf(170,8) == 0)) { // andros
		print_str("Talking: Andros is still too angry to talk. 'You have your");
		print_str("  orders. Go with Solberg, and good luck.'");
		}
	else if ((get_memory_cell(4) == 0) && (gf(82,4) >= 2))  { 
		print_str("Talking: Solberg says, 'No time to talk. We must hurry. Stay close to me.'");
		}
	else if ((get_memory_cell(4) == 2) && (gf(82,4) >= 2))  { 
		print_str("Talking: Vanderin says, 'Come on! This is exciting!'");
		}
		else begin_talk_mode(get_memory_cell(0));
break;