// basicnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home. A conversation can be set for it,
// if it's friendly.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
// cell 4 special abil

begincreaturescript;

variables;

short i,target;
short tried_return = 0;
short last_abil;

body;

beginstate INIT_STATE;
	set_level(ME,32);
	set_boss_level(ME,1);
	set_attack_bonus(ME,25);
	
	alter_stat(ME,28,10);
	alter_stat(ME,30,10);
	
	set_attitude(ME,4);
	
	if (get_memory_cell(0) == 2)
		set_walk_speed(ME,0);

	last_abil = get_current_tick();
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	if (gf(37,6) == 0) {
		if ((get_nearest_party_char(7) >= 0) || (who_shot_me() >= 0)) {
			sf(37,6,1);
			set_attitude(30038,10);
			set_act_at_dist(30038,1);
			set_attitude(30039,10);
			set_act_at_dist(30039,1);
			set_attitude(4017,10);
			set_act_at_dist(4017,1);
			set_attitude(4018,10);
			set_act_at_dist(4018,1);
			set_attitude(4019,10);
			set_act_at_dist(4019,1);
			set_attitude(4020,10);
			set_act_at_dist(4020,1);
			set_attitude(4021,10);
			set_act_at_dist(4021,1);
	
			begin_talk_mode(5);
			}
		end();
		}
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	// if we're hostile, hunt party down
	if ((get_attitude(ME) >= 10) && (dist_to_party() <= 25)) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}
			else {
				if (my_dist_from_start() >= 6) {
					return_to_start(ME,1);
					}
					else if (get_memory_cell(0) == 0) {
						tried_return = 0;
						fidget(ME,25);
						}

				}
				
	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking

	if (target_ok() == FALSE)
		set_state(START_STATE);
	if ((my_dist_from_start() >= 20) && (get_ran(1,0,2) == 1)) {
		alert_char(30038);
		alert_char(30039);
		alert_char(4017);
		alert_char(4018);
		alert_char(4019);
		alert_char(4020);
		alert_char(4021);
		}
	
	if ((my_dist_from_start() >= 26) && (tried_return < 3)) {
		tried_return = tried_return + 1;
		set_foe_target(ME,-1);
		return_to_start(ME,2);
		set_state(4);
		}

	if ((is_combat()) && (get_memory_cell(4) > 0) && (get_nearest_hate_char(4) >= 0) && (tick_difference(last_abil,get_current_tick()) > 0)) {
		run_char_animation(2,1,35);	
		last_abil = get_current_tick();

			print_named_str(ME,"spins around, cleaving the air with a mighty blow.");
			damage_nearby(get_ran(get_level(ME) + get_attack_bonus(ME),1,8),4,0,0);
			pc_heard_sound_delay(3,100);				
			spray_missiles(15,8,4);
			spray_missiles(20,8,4);

		end();
		}


	do_attack();
break;

beginstate 4; // returning to start
	if (my_dist_from_start() < 10)
		set_state(START_STATE);

	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}
	
	return_to_start(ME,2);
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;