//twopts.txt - Like basic monst, but this character spends all its time 
// oscillating between its start point and a given nav point.
// Memory Cells:
//   Cell 0 - Dialogue node when spoken to
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this is killed, set to 1.
//	 Cell 3 - Start nav destination

begincreaturescript;

variables;

short i,target,x,y;
short cur_dest = 0;
short last_walk;
short num_advance = 0;
short time_per_step = 10;
body;

beginstate INIT_STATE;
	set_name(ME,"Blosk Brigand");
	set_level(ME,6);
	set_act_at_dist(ME,1);
	
	last_walk = get_current_tick();
	
	cur_dest = get_memory_cell(3);
	
	if (gf(114,1) > 1)
		erase_char(ME);
	break;

beginstate DEAD_STATE;
	inc_flag(114,2,1);
	
	x = my_loc_x();
	y = my_loc_y();
	if (get_floor(1,x,y) < 197)
		set_floor(1,x,y,34);
	print_str_color("The brigand falls. Several sacks of mushroom meal have been recovered.",2);
	if (gf(114,2) == 1)
		begin_talk_mode(18);
break;

beginstate START_STATE; 
	if (gf(114,16) > 20)
		num_advance = 1;
	if (gf(114,16) > 20 + time_per_step * 1)
		num_advance = 2;
	if (gf(114,16) > 20 + time_per_step * 2)
		num_advance = 3;
	if (gf(114,16) > 20 + time_per_step * 3)
		num_advance = 4;
	if (gf(114,16) > 20 + time_per_step * 4)
		num_advance = 5;
	if (gf(114,16) > 20 + time_per_step * 5)
		num_advance = 6;
		
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_foe_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (get_foe_target(ME,12,0)) {
		if (dist_to_party() > 8)
			approach_char(ME,30000,7);
			else {
				do_attack();
				set_state(3);
				}
		}
		
	// Have I been hit? Strike back!
	if (who_shot_me() >= 0) {
		set_foe_target(ME,who_shot_me());
		do_attack();
		set_state(3);
		}

	// walk to next point?
	if ((gf(114,17) == 0) && (cur_dest - get_memory_cell(3) < num_advance)) {
		if (dist_to_nav_point(ME,cur_dest) <= 2) {
			if (cur_dest >= 4)
				erase_char(ME);
			cur_dest = cur_dest + 1;
			}
			else approach_nav_point(ME,cur_dest,1);
		}

	// if we're hostile, hunt party down
	if ((gf(114,17) > 0) && (get_attitude(ME) >= 10)) {
		set_foe_target(ME,random_group_member(0));
		set_state(3);
		}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(0) == 0) {
		print_str("Talking: You make a bit of small talk, but don't learn");
		print_str("  anything interesting.");
		}
		else begin_talk_mode(get_memory_cell(0));
break;