void main( void )
{
}

void touch( void )
{

 freeze(1);
 move_stop(1, 6, 300,1 );
 sp_dir(1,4);
 if (&caveguy == 2)
 {
 say_stop("看来是这里了，不过被锁上了。", 1);
 say_stop("敲敲门试试吧..", 1);
 unfreeze(1);

 return;
 }

 if (&caveguy == 3)
 {
 say_stop("希望那个老头会教我。", 1);
 unfreeze(1);
 return;
 }

 say("锁住了啦", 1);
 unfreeze(1);
}

void hit( void )
{
 goto knocked;
}

void talk( void )
{
 knocked:

 if (&caveguy == 2)
 {
 int &me;
 &me = &current_sprite;
 script_attach(1000);
 freeze(1);
 wait(500);
  playsound(45, 12000, 0,0,0);
 wait(500);
 say_stop("喂，有人吗？", 1);
 wait(500);
 say_stop("喂？", 1);
 wait(300);
 say_stop("`0是谁想知道？", &me);
 wait(300);
 say_stop("我...我叫丁克小森林，我想去解救...", 1);
 wait(200);
 say_stop("一个被困住的人。", 1);
 wait(300);
 say_stop("`0年轻的坏森林, 经常会有人在不该去的地方被困住的，", &me);
 wait(200);
 say_stop("`0我为什么要帮这个人？", &me);
 wait(500);
 sp_dir(1, 2);
 wait(500);
 sp_dir(1, 4);
 wait(500);
 say_stop("是小森林，先生，他说", 1);
 wait(200);
 say_stop("他是被Cast成员关起来的，而那个锁只能用魔法解除。", 1);
 wait(300);
 say_stop("`0你在做梦吗？", &me);
 wait(300);
 say_stop("不是。", 1);
 say_stop("`0那样啊。", &me);
 wait(200);
 say_stop("`0那好吧，既然是找Cast的麻烦，我还是帮个忙好了。", &me);
 wait(200);
 say_stop("`0进来吧。", &me);
 fade_down();
 fill_screen(0);
 //move Dink
 &player_map = 38;
 sp_x(1, 261);
 sp_y(1, 350);
 load_screen();
 draw_screen();
 draw_status();
 fade_up();
 kill_this_task();
 return;
 }
 if (&caveguy == 3)
 {
 int &me;
 &me = &current_sprite;
 script_attach(1000);
 freeze(1);
  playsound(45, 12000, 0,0,0);
  wait(700);
 say_stop("哈，我又来啦！", 1);
 wait(300);
 say_stop("`0啊，小棒子，进来吧 ..", &me);
 fade_down();
 fill_screen(0);
 //move Dink
 &player_map = 38;
 sp_x(1, 261);
 sp_y(1, 350);
 load_screen();
 draw_screen();
 draw_status();
 fade_up();
 kill_this_task();
  return;
 }

 freeze(1);
 wait(500);
  playsound(45, 12000, 0,0,0);
 wait(500);
 say_stop("喂，有人在吗？", 1);
  unfreeze(1);

}
