//Goblin George

void main( void )
{
int &mcounter;
sp_brain(&current_sprite, 16);
sp_speed(&current_sprite, 1);
sp_distance(&current_sprite, 50);
sp_timing(&current_sprite, 66);
sp_exp(&current_sprite, 50);
sp_base_walk(&current_sprite, 760);
sp_defense(&current_sprite, 2);
sp_hitpoints(&current_sprite, 40);
preload_seq(765);
preload_seq(761);
preload_seq(763);
preload_seq(767);
preload_seq(769);
wait(3500);

say("`6侬好，砰友，我们能仪齐去看吗？", &current_sprite);
}

void hit( void )
{
playsound(28, 22050,0,&current_sprite, 0);
&mcounter = random(3, 1);
sp_frame_delay(&current_sprite, 30);
sp_timing(&current_sprite, 0);
sp_speed(&current_sprite, 2);
sp_brain(&current_sprite, 9);
if (&mcounter == 1)
  say("`6哦，乏要嘛，淫类，偶们卡以党砰有的！", &current_sprite);

if (&mcounter == 2)
  say("`6发要答我！", &current_sprite);

if (&mcounter == 3)
  say("`6偶发灰书的！", &current_sprite);

}

void die( void )
{
  int &hold = sp_editor_num(&current_sprite);
  if (&hold != 0)
  editor_type(&hold, 1); 
  say("就以次告戒地精吧。", 1);
}
void talk( void )
{
        freeze(&current_sprite);
        freeze(1);

 choice_start()
 "询问地精的名字"
 "问他在此有何贵干"
 "询问关于地精圣堂的事"
 "离开"
 choice_end()

  if (&result == 1)
   {
    say_stop("地精啊，你叫什么名字？", 1);
    wait(500);
    say_stop("`6偶，偶教 George。偶门客以党砰有？", &current_sprite);
    wait(500);
    say_stop("我不明白你在说什么。", 1);
   }


  if (&result == 2)
   {
    say_stop("你为什么不在地精圣堂呢？", 1);
    wait(500);
    say_stop("`6偶要哈银类生活。", &current_sprite);
    wait(500);
    say_stop("你要知道，很多人类都怕地精的啊。", 1);
    wait(500);
    say_stop("`6george 系银。", &current_sprite); 
    wait(500);
    say_stop("啊，知道了，祝你好运。", 1);
   }

  if (&result == 3)
   {
    say_stop("那个地精圣堂到底是个什么样的地方？", 1);
    wait(500);
    say_stop("`6他门号坏。只董一件系。", &current_sprite);
    wait(500);
    say_stop("那是什么呢？我可能需要知道。", 1);
    wait(500);
    say_stop("`6暴力。要招唤 Mog 酒闭需沙光所有互卫。", &current_sprite); 
    wait(500);
    say_stop("啊，虽然我不清楚 Mog 是什么，不过，谢谢了。", 1);
   }


unfreeze(&current_sprite);
unfreeze(1);

 

}

