
void main(void)
{
int &whob = sp(26);
sp_hitpoints(&current_sprite, 0);


 if (&story > 2)
 {
 sp_active(&whob,0);
// draw_hard_map();
 return;
 }

 if (&old_womans_duck > 2)
 {
 if (&pig_story == 0)
 {
move_stop(&current_sprite, 2, 160, 1);
freeze(&current_sprite);
wait(200);
say_stop("`#丁克！ 都这么晚了！ 先把猪喂了再吃饭！", &current_sprite);
wait(200);
unfreeze(&current_sprite);
return;
 }
 &story = 2;
 move_stop(1, 8, 370, 1);
freeze(1);
move_stop(&current_sprite, 2, 200, 1);
freeze(&current_sprite);
wait(1000);
 say_stop("`#丁克， 你能帮我个忙吗？", &current_sprite);
 wait(500);
 say_stop("要我做什么？", 1);
 wait(500);
 say_stop("`#帮我去森林里看看能不能捡些，", &current_sprite);
 wait(500);
 say_stop("`#AlkTree nuts， 现在正是他们生长的季节。", &current_sprite);
 wait(500);
 say_stop("没问题，很快就回来。", 1);
 wait(250);
 say_stop("`#真乖。", &current_sprite);
 unfreeze(1);
 unfreeze(&current_sprite);
 return;
 }



 if (&story == 0)
 {
 //new game was just started.
 //make script live on
 int &cur_sprite = &current_sprite;
 playmidi("dance.mid");
 freeze(1);
 freeze(&cur_sprite);
 wait(1000);
 say_stop("`#丁克， 去喂猪吧？", &cur_sprite);
 wait(200);
 say_stop("哪泥？？现在？？！！", 1);
 wait(200);
 say_stop("`#难道还明年啊 -_-凸。", &cur_sprite);
 unfreeze(1);
 unfreeze(&cur_sprite);
 playsound(22, 22050, 0,0,0);
 &update_status = 1;
 draw_status();
 &story = 1;
 return;
 }

}

void talk(void)
{
 freeze(1);
 freeze(&current_sprite);
 choice_start();
   "关于喂猪"
   "关于父亲"
   "关于村庄"
   "发怒"
(&pig_story == 1) "猪喂好啦"
   "离开"
 choice_end();

 wait(200);

 if (&result == 1)
  {
  say_stop("娘，猪是怎么喂的啊，我忘了。",1);
  wait(200);
  say_stop("`#啊哈哈，你是开玩笑的吧？把猪食带上", &current_sprite);
  say_stop("`#到猪圈里去撒就好了啊，不要逗它们！", &current_sprite);
  wait(100);
  }

 if (&result == 2)
  {
  say_stop("老爸是怎么样的人啊？",1);
  wait(200);
  say_stop("`#和我们一样是个平民。", &current_sprite);
  wait(200);
  say_stop("剑术很高明吧？",1);
  wait(200);
  say_stop("`#怎么可能。他是个优秀的农民和丈夫。", &current_sprite);

  }
 if (&result == 3)
  {
  say_stop("这个小村....",1);
  wait(200);
  say_stop("`#这个村子的人都很友善。哦对了，Ethel 正在找你呢。", &current_sprite);
  wait(200);
  say_stop("Ethel?  她很老了对吧？",1);
  wait(200);
  say_stop("`#对啊，她老了 <大笑>", &current_sprite);
  }

 if (&result == 4)
  {
  say_stop("我恨你！",1);
  wait(200);
  say_stop("`#等你长大了当爸爸了就明白了。",&current_sprite);
  }

 if (&result == 5)
  {
  say_stop("娘，我事情都做好了。",1);
  wait(200);
  say_stop("`#真乖，我做饭了，你四处逛逛吧。", &current_sprite);
  }


 unfreeze(1);
 unfreeze(&current_sprite);

  }

}

void hit(void)
{
 say_stop("`#住手！好痛！", &current_sprite);

}

