void main( void )
{
 int &girl;
 &girl = 0;
 int &mom;
 &mom = random(3, 1);
 if (&mom == 1)
 {
  freeze(&current_sprite);
  say_stop("`4先生你好。", &current_sprite);
  unfreeze(&current_sprite);
 }
}

void talk( void )
{
 freeze(1);
 freeze(&current_sprite);
 choice_start()
 "关于此店"
 "看看有什么货"
 "离开"
 choice_end()
  if (&result == 1)
  {
   say_stop("嘿，你们卖什么呢？", 1);
   wait(250);
   say_stop("`4我们是 Robinson 橱柜。", &current_sprite);
   wait(250);
   say_stop("`4我们可以提供所有的木头家具需求。", &current_sprite);
   wait(250);
   say_stop("哦，那就不是我该来的地方了。我和木头家具的历史可不太好。", 1);
   wait(250);
   say_stop("他们会着火，我认识的人会死掉。 :(", 1);
   wait(250);
   say_stop("`4那好吧，要是你有需要的话我会..在..那里。", &current_sprite);
  }
  if (&result == 2)
  {
   if (&girl == 1)
   {
    say_stop("有什么东西打折吗？", 1);
    wait(250);
    say_stop("`4先生，请不要问折扣，我需要照顾我女儿。", &current_sprite);
    wait(250);
    say_stop("`6老爸！！！", &prom);
    wait(250);
    say_stop("`4看到吧？实在是没办法。", &current_sprite);
    unfreeze(1);
    unfreeze(&current_sprite);
    return;
   }
   int &prom;
   &prom = create_sprite(310, 460, 0, 0, 0);
   sp_brain(&prom, 16);
   sp_base_walk(&prom, 330);
   sp_speed(&prom, 1);
   sp_timing(&prom, 0);
   //set starting pic
   sp_pseq(&prom, 339);
   sp_pframe(&prom, 1);
   freeze(&prom);
   &girl = 1;
   say_stop("那这个月有什么特销吗？", 1);
   wait(250);
   say_stop("`4不好意思啊，我们没有的。我们几乎都是", &current_sprite);
   wait(250);
   say_stop("`4给单独房子做工。哦，还做些橱柜什么的。", &current_sprite);
   wait(250);
   say_stop("明白了，不过我没房，还是谢谢你了。", 1);
   wait(250);
   say_stop("`4没，没问题 ...", &current_sprite);
   say("`6老爸！！", &prom);
   say_stop("`4哎 ...", &current_sprite);
   say("`6老爸！！", &prom);
   move_stop(&prom, 8, 250, 1);
   say_stop("`4怎么了亲爱的？", &current_sprite);
   wait(250);
   say_stop("`6我要新的裙子！", &prom);
   wait(250);
   say_stop("`4可亲爱的，我们上星期才给你买过啊。", &current_sprite);
   wait(250);
   say_stop("`6那件在太阳底下不好看啦，", &prom);
   wait(250);
   say_stop("`6我们去退掉再买嘛！", &prom);
   wait(250);
   say_stop("`4我，我不知道 ....", &current_sprite);
   wait(250);
   say_stop("`6我说现在就去买啦！！！！", &prom);
   wait(250);
   say_stop("`4哦，好好好，好好好。", &current_sprite);
   unfreeze(&prom);
  }
 unfreeze(1);
 unfreeze(&current_sprite);
}

void hit( void )
{
 freeze(&current_sprite);
 say("`4住手啦！你会把木头打坏的。", &current_sprite);
 unfreeze(&current_sprite);
}
